Le modèle povray.mod

Ce modèle permet d'ajouter un export vers povray pour les scènes 3D, ou encore d'utiliser TeXgraph un peu comme une interface pour povray. Ce fichier nécessite la version 1.94-beta-8 minimum.

-> Sous linux TeXgraph appelle automatiquement povray dès la fin de l'export et on voit la création de l'image s'effectuer.

-> Sous windows il vous faudra lancer l'interface graphique de povray et charger le fichier exporté pour le compiler, sauf si vous avez installé le programme compilé par projetmbc qui est une version pour windows (32bits) en ligne de commande (sans GUI). Cette version est ici povray4win.zip, bien lire le fichier LisezMoi.txt. Cette version est utilisée par TeXgraph depuis la version 0.5 du modèle povray.mod.

Utilisation: on charge le modèle povray.mod, deux boutons apparaissent à gauche de la fenêtre, le deuxième bouton est celui qui se charge de l'export vers povray. On peut ensuite définir une scène 3D dans un élément graphique Utilisateur comme on le faisait avec les commandes Build3D et Display3D(), sauf que celles-ci sont remplacées par povScene et display3D(), on ajoute des éléments graphiques dans la scène grâce à des macros dont le préfixe est "pov" (povAxes, povSurf, ...) et non plus "bd". Toutes ces macros sont détaillées dans la doc povray.pdf. Les autres exports classiques, restent valables, en particulier les exports obj et geom.

Télécharger: povray.zip ( version 0.5 du 22/04/09)

Le paquet contient 4 fichiers:

- povray.mac (macros)
- povray.mod (modèle à charger)
- povray.pdf (aide)
- povray.txt (à lire)

Attention: Depuis la version 0.2 il est possible d'inclure une formule TeX dans la scène. Cette possibilité nécessite l'installation de l'utilitaire pstoedit, et son chemin d'accès doit être dans la variable PATH. Le rendu peut être un peu long car cela demande une compilation TeX en arrière-plan pour récupérer la formule compilée. Voir l'exemple de la sphère un peu plus bas.

Les questions/propositions concernant ce modèle sont à poster dans ce forum.

Exemples: charger le modèle povray.mod (F3) et créer un élément graphique Utilisateur avec les commandes suivantes:

Code:


[view(-5,5,-5,5), view3D(-5,5,-5,5,-4,4),  Marges(0,0,0,0), size(12,1),
 backcolor:=darkgray, shadow:=1,
 povScene(
        povPlan([2,0,-vecI], [color:=darkseagreen, scale:=0.85, opacity:=0.3]),
        povTorus( [0,0],3,1,vecK, [color:=steelblue, smooth:=1, clip:=-1,
                                    clipwin:=[2,0,-vecI]]),
        povAxes([0,0], [color:=gold, arrows:=1, arrowscale:=1.5])
        ),
 display3D() ]


Code:


[view(-5.5,5.5,-5.5,5.5), view3D(-5,5,-5,5,-5,5), Marges(0,0,0,0), size(12,1),
 A:=4*M(1,1,1)/sqrt(3), Az:=pz(A), Axy:=pxy(A), Ax:=px(A), Ay:=py(A),
 backcolor:=darkgray, shadow:=1,
 povScene(
    povPlan([0,0,vecK], [color:=darkseagreen, scale:=0.9, opacity:=0.8]),
    povSphere([0,0],4, [color:=darkblue, opacity:=0.6]),
    povLabel(A,"A\begin{pmatrix}\cos(\theta)\sin(\varphi)\\
                  \sin(\theta)\sin(\varphi)\\
                  \cos(\varphi)\end{pmatrix}",
            [color:=gold, showdot:=1, dotscale:=1.5, TeXify:=1,scale:=0.85,
              labelpos:=[0.5,1], labelstyle:=left]),
    povLabel(M(4.25,4,0),"plan P",[labelstyle:=right+bottom,
                                    labeldir:=[vecJ,-vecI]]),
    povLine([Az,A,0,0,Axy,A,jump,Axy,4*normalize(Axy),jump,Ax,Axy,Ay],
            [color:=red]),
    povArc(Az,Origin,A,4,1,[color:=brown, arrows:=1,
                            labelarc("\varphi"), TeXify:=1]),
    povArc(pxz(A),Az,A,Norm(A-Az),1, [color:=brown, arrows:=1,
                                      labelarc("\theta"), TeXify:=1]),
    povArc(Az,Origin,[4,0],4,1,[color:=brown]),
    povAxes([0,0],[color:=gold, arrows:=1, arrowscale:=1.5]),
        ),
 display3D() ]       


Code:


[view(-7,7,-7,7), Marges(0,0,0,0), size(12,1), view3D(-6,6,-6,6,-6,6),
 H:=5, R:=4, a:=2, Plan:=[M(a,0,0),vecI],
 C1:=Cone(Origin, H*vecK,R,45,0),  C2:=Cone(Origin, -H*vecK,R,45,0),
 L1:=Intersection(Plan,C1), L2:=Intersection(Plan,C2),
 Asymp1:=getdroite( [M(a,0,0),M(0,R,H)] ),  Asymp2:=getdroite( [M(a,0,0),M(0,-R,H)] ),
 backcolor:=gray, imagescale:=0.75,
 povScene(povComment("plan1"),
          povPlan(Plan, [color:=darkseagreen, opacity:=0.6]),
          povComment("cone"),
          povCone(Origin, H*vecK,R,[color:=slategray, smooth:=1]),
          povCone(Origin, -H*vecK,R,[color:=slategray, smooth:=1]),
          povComment("asymptotes"),
          povLine([ Asymp1,Asymp2], [color:=blue, width:=8]),
          povComment("hyperbole"),
          povLine(Merge3d([L1,L2]), [color:=red, width:=12]),
          povComment("Axes"),
          povAxes([0,0], [color:=gold, labels:=1, arrows:=1, arrowscale:=1.5]),
            ),
 display3D() ]


Code:


[Marges(0,0,0,0), view(-5,5,-5,5),size(12,1),
 S:=GetSurface([u+i*v,3*(sin(u)+cos(v))], pi*(-1+i),pi*(-1+i)),
 R:=rectangle3d(S), z1:=Zde(R[1,2]), z2:=Zde(R[3,2]),
 nb:=8, pas:=(z2-z1)/nb,
transformbox3d(R), Mat:=GetMatrix3D(),
IdMatrix3D(),view3D(-4,4,-4,4,-4,4),
palette:=[purple,darkblue, blue,darkgreen, green, yellow,orange,red],
backcolor:=gray, z:=z1,
povScene( for k from 1 to nb-1 do
            Inc(z,pas),
            S:=ClipFacet(S,[M(0,0,z),-vecK], S'),
            Inc(k,1),
            povFacet(S,[color:=palette[k], smooth:=1, matrix:=Mat]),
            Re(jump)-i,
            Echange(S,S')
        od,
        povFacet(S,[color:=crimson, smooth:=1, matrix:=Mat]),
        povAxes([0,0],[color:=gold, arrows:=1, arrowscale:=1.5])),
display3D() ]


Bonjour Patrick,

je ne crois pas que je vais avoir le temps de tester cela immédiatement ... mais c'est vraiment magnifique !!!

Question car je vois des commandes type "povtore", "povplan", qu'est qui reste valable des autres représentations 3D sous TeXgraph
(les polyedre par exemple)


Samuel

samuel.biton a écrit:Bonjour Patrick,

Bonjour Samuel,

je ne crois pas que je vais avoir le temps de tester cela immédiatement ... mais c'est vraiment magnifique !!!

Oui, povray est capable de très belles choses! Ce serait dommage de ne pas en profiter pour faire des illustrations mathématiques.

Question car je vois des commandes type "povtore", "povplan", qu'est qui reste valable des autres représentations 3D sous TeXgraph (les polyedre par exemple)

Rien n'a changé pour le reste, ces macros pour povray sont en plus et suivent le même principe que les macros déjà existantes pour Build3D (voir le fichier scene3d.pdf). Je pense d'ailleurs essayer de les fusionner dans une prochaine version, disons que pour le moment c'est expérimental.

Re salut,

finalement je n'ai pas résisté : je viens de récupérer l'archive et de la mettre ou il faut mais quand le charge le povray.mod j'ai un message d'erreur
de TeXgraph :

Code:


ligne 52 : Caractère @ non reconnu


mon installation de TeXgraph datait juste unn peu et en mettant la dernière version cela va mieux et tout semble fonctionner. C'est gourmand en ressources visiblement (l'affichage dans povray prend quelques secondes et le changement d'angle de vue dans l'interface TeXgraph aussi), mais le résultat est magnifique.

Petite question quand même du coup, le "@" veut dire quoi ?

Samuel

samuel.biton a écrit: C'est gourmand en ressources visiblement (l'affichage dans povray prend quelques secondes et le changement d'angle de vue dans l'interface TeXgraph aussi), mais le résultat est magnifique.

Oui, le rendu peut-être très long (tout est relatif) surtout pour les surfaces implicites. Dans TeXgraph aussi, mais cela dépend du nombre de facettes.

Petite question quand même du coup, le "@" veut dire quoi ?

On peut utiliser les macros comme variable pour chaine de caractères, l'accès à une telle "variable" se fait avac l'opérateur @ devant le nom. Par exemple tu peux essayer:

Code:


[ SetStr(prenom, "samuel"), Message([ "mon prénom est ", @prenom]) ]


Salut,

On peut utiliser les macros pour comme variable pour chaine de caractères, l'accès à une telle "variable" se fait avac l'opérateur @ devant le nom. Par exemple tu peux essayer:

d'accord, bien pratique cela, je crois que c'est ce que tu m'avais dit rapidement une fois, mais j'avais oublié. Comme tu me l'avais dit aussi le même jour, on peu donc gérer des chaines de caractères. Par contre, il n'y a pas de fonctions qui vont avec (coupure, matching ou autres ) ?

Samuel

Bonjour,

tout d'abord je tiens à faire part de mes remerciements à son auteur pour texgraph : chapeau pour votre travail!

Je suis utilisateur de texgraph et occasionnellement de povray dont j'apprécie le langage de programmation et la qualité remarquable du rendu en 3D : merci donc pour ce module d'export en povray

Le seul petit bémol concernant Povray est qu'il n'accepte pas (à ma connaissance) d'inclusion de texte formaté en latex comme par exemple asymptote : c'est dommage (même ce n'est pas suffisant pour bouder ce remarquable logiciel)

s'il était possible de le faire alors ce serait la solution ultime!

Bonjour,

Et merci pour les remerciements. Il serait effectivement dommage de se passer de povray simplement parce que l'on ne peut pas inclure directement de formules latex. Je sais qu'il existe une solution qui consiste à récupérer les formules compilées par TeX en sous main sous forme de chemins, et de convertir ceux-ci en objets 3D. Je pense (sans en être sûr) que c'est la méthode utilisée par asymptote, et je vais y réfléchir pour voir ce que je peux faire mais je ne garantis rien!

Sinon il y a une méthode détournée qui consiste à faire l'image povray sans formule, puis de charger cette image en image de fond dans TeXgraph et d'ajouter par-dessus les formules et d'exporter le tout en pgf. Je n'ai pas voulu mettre d'exemples de cette méthode car cela aurait induit en erreur en donnant l'impression que j'avais effectivement inclus des formules TeX dans povray.

Je suis en train de faire quelques recherches à ce sujet et je suis tombé sur ce fil:

http://news.povray.org/povray.binaries.utilities/thread/%3C3e6906c1%40news.povray.org%3E/?mtop=6

il est évoqué un script eps2pov qui semble intéressant.

sinon un excellent tutorial sur povray avec pleins de macros dédiées maths est ici:

http://www.f-lohmueller.de/pov_tut/pov__fra.htm

@+

Merci pour le script eps2pov je vais regarder ça de près dès que j'ai un moment.

samuel.biton a écrit:
... Comme tu me l'avais dit aussi le même jour, on peu donc gérer des chaines de caractères. Par contre, il n'y a pas de fonctions qui vont avec (coupure, matching ou autres ) ?

Il y a quelques fonctions de bases:

SetStr( nom, chaine): qui définit une variable (macro) contenant chaine, cette variable peut être ensuite utilisée comme ceci: @nom ou bien GetStr(nom).

StrComp( chaine1, chaine2): renvoie 1 en cas d'égalité

StPos( motif, chaine): renvoie un entier (position du premier motif dans chaine)

StrLength(chaine): renvoie la longueur de la chaine

StrCopy(chaine, indice départ, quantité): renvoie la chaine extraite

UpperCase(chaine): renvoie la chaine en majuscules

LowerCase(chaine): renvoie la chaine en minuscules

Bonsoir Patrick

Il y a quelques fonctions de bases:
SetStr( nom, chaine): qui définit une variable (macro) contenant chaine, cette variable peut être ensuite utilisée comme ceci: @nom ou bien GetStr(nom).
StrComp( chaine1, chaine2): renvoie 1 en cas d'égalité
StPos( motif, chaine): renvoie un entier (position du premier motif dans chaine)
StrLength(chaine): renvoie la longueur de la chaine
StrCopy(chaine, indice départ, quantité): renvoie la chaine extraite

d'accord, merci.

A bientôt

Samuel

Bonsoir Patrick,
Je ne me suis pas connecté depuis quelques temps sur le forum, et je découvre ton formidable travail sur povray que je ne connaissais pas du tout.
Il me tarde de tester ce module.

Télécharger: povray.zip ( version 0.1 du 30/01/09)

Où ?
En effet, les autres modèles se trouvent dans le répertoire usr/local/share/TeXgraph/macros.
Donc faut-il l'enregistrer en root dans ce répertoire ?
Ce modèle apporte-il un plus en terme de rendu par rapport à ce que faisait TeXgraph ?
Merci.

Bonsoir Fabrice,

N'oublie pas de lire le contenu de povray.txt ! Il faut aussi que tu saches que cela ne fonctionnera qu'avec les dernière version test (1.94-beta-7.4).

Normalement tu dois avoir dans ton $HOME un dossier nommé TeXgraphMac, tu peux décompresser l'archive dans ce dossier, pour ma part j'ai ajouté ce dosser aux signets ce qui fait que lorsque je veux charger un modèle, le dossier TeXgraphMac apparaît à gauche dans la fenêtre de dialogue.

Quant à ton autre question, oui, povray apporte un plus énorme par ses capacités et la qualité de son rendu pour les scènes 3D. Tiens un exemple qui vas te rappeler quelque chose:

Code:


[view3D(-9,9,-8,8,-6,6), view(-12,12,-9,10), Marges(0,0,0,0), size(12,1),
 $a:=4*sqrt(3)/3,
 C1:=M(a,0,0), C2:=M(-a/2, a*sqrt(3)/2, 0), C3:=M(-a/2, -a*sqrt(3)/2, 0),
 C4':=(C1+C2+C3)/3, {centre de gravité}
 C4:= pxy(C4')+M(0,0,4*sqrt(2/3)),
 S1:=Sphere(C1,2,25,25), S2:=Sphere(C2,2,25,25),
 S3:=Sphere(C3,2,25,25), S4:=Sphere(C4,2,25,25),
 P:=[M(0,0,-2),vecK], h:=Zde(C4)+4,
 A:=M(4,-4,-2), B:=A+M(0,0,h),
 G:=(C1+C2+C3+C4)/4, G':=pxy(G), k:=1+2/Norm(G'-G),
 T:=hom3d( Tetra(C1,C2-C1,C3-C1,C4-C1), G, k),
 backcolor:=darkgray,
 povScene(
        povPlan(P,[color:=slategray]),
        povFacet(T,[color:=Rgb(0.8,0.6,1),opacity:=0.25]),
        povSphere(C1,2, [color:=firebrick, backculling:=1, smooth:=1]),
        povSphere(C2,2, [color:=steelblue, backculling:=1,smooth:=1]),
        povSphere(C3,2, [color:=orange, backculling:=1,smooth:=1]),
        povSphere(C4,2, [color:=darkseagreen, backculling:=1,smooth:=1]),
        povLine(Bord(getplan(P)),[width:=12]),
        povLine(Aretes(T),[width:=12]),
        povLine([B,C4+M(0,0,2)], [color:=black, width:=2]),
        povLine([A,B], [color:=gold, width:=8, arrows:=2, arrowscale:=1.5]),
        povLabel((A+B)/2,"h",[color:=gold, labelstyle:=right, labelpos:=[0.25,-1-i]])
        ),
 display3D() ]


Le rendu par povray ne prend que quelques secondes, et sans chercher à optimiser le finish!

Re,

N'oublie pas de lire le contenu de povray.txt

Oui, mais pour cela il me fallait l'enregistrer !
J'ai voulu tester le code que tu proposes qui me rappelle effectivement quelques souvenirs !
J'ai copié ce code dans un élément graphique utilisateur, puis clické sur Export povray et ......rien

Deux choses:

1) tu es bien sûr d'avoir la dernière version test?

2) tu as installé povray?

Bonjour Patrick,
J'avais intallé la dernière version de TeXgraph (1.94-beta 7.4) et la version povray-3.6.
Je viens de refaire une tentative, j'ai un rectangle blanc sur fond gris et il ne semble rien se produire après avoir clické sur le bouton Export povray.
Merci.

Bonjour Fabrice,

Quand tu cliques, une fenêtre s'ouvre et te demande le nom du fichier entre deux:" ". Je viens de retester au boulot à l'instant (sous windows) et ça marche ...

Salut Patrick,
Voici une copie de l'interface de TeXgraph pour te montrer que j'ai bien les deux boutons dont tu parles.


L'élément graphique Utilisateur contient le code avec les sphères tangentes.

Quand tu cliques, une fenêtre s'ouvre et te demande le nom du fichier entre deux:" ".

Bah non !

Tiens tiens! Plutôt curieux!

Et le reste fonctionne correctement? Si tu ouvres un de tes fichiers graphiques, pas de soucis? Le dessin à la souris marche par exemple?

Bonsoir,

Déjà bravo pour ce nouvel export.

J'ai une petite question, j'aurais besoin de dessiner une "tranche" de sphère, j'ai essayer d'utiliser
rotCurve mais je ne doit pas l'utiliser comme il faut.

Merci

Bonjour Joffrey,

Essaie ça:

sans povray:

Code:


[R:=4,
 S:=rotCurve(R*M(0,cos(t),sin(t)),[Origin,-vecK],-pi/2,pi/2,0,3*pi/8,50,15),
 DrawFacet(S, [color:=steelblue, smooth:=1])
]


avec povray (charger le modèle avant):

Code:


[R:=4,
 S:=rotCurve(R*M(0,cos(t),sin(t)),[Origin,-vecK],-pi/2,pi/2,0,3*pi/8,50,15),
 povScene( povFacet(S, [color:=steelblue,smooth:=1]) ),
 DrawFacet(S, [color:=steelblue, smooth:=1])
] 


super, je peux m'en payer une tranche

lorsque j'ouvre povray l'image est reduite en hauteur, quel paramètre faut-il changer?

merci

Bonsoir Patrick,

Et le reste fonctionne correctement? Si tu ouvres un de tes fichiers graphiques, pas de soucis? Le dessin à la souris marche par exemple?

Tout me semble fonctionner parfaitement. A l'aide d'un tutoriel sur povray, j'ai écrit une petite scène que j'ai testée via la console : povray scene1.pov, et cela fonctionne ; j'ai une image scene.png qui est créée.
Je dois bien avouer que je suis assez impressionné par la qualité du rendu.
Pour ce qui est du fonctionnement de TeXgraph, là je ne vois pas trop.
Résumons: un simple click sur le bouton Export povray sous linux doit lancer la console, et l'image doit apparaître.
Est-ce que je procède de la bonne façon ?
Je viens de tester le fichier (avec povray) que tu viens de poster pour Joffrey, j'ai bien une "tranche "de sphère, mais pas comme celle que tu as jointe. J'ai l'impression que seul TeXgraph a travaillé puisque j'ai eu le graphique 3D dès que j'ai appuyé sur ok de l'élément graphique Utilisateur.
De plus, je peux visualiser le résultat avec Aperçu .
Mais toujours rien en clickant sur Export povray.

@Joffrey:

Manifestement, tu es sous windows, tu as du charger le fichier *.pov dans l'éditeur de povray. Regarde en haut du fichier (2ième ligne) tu as en commentaires les options à passer à povray. On passe les options dans la zone de saisie prévue à cet effet en haut de la fenêtre. Tu me suis?