Un pavage du plan

Je souhaite réaliser un pavage du plan par des parallélogrammes

?

Il y a un moyen de déclarer des unités de base et ensuite de les reproduire par translation ?

J'y vois un empliement de parallélépipèdes, donc je te propose ceci:

Code:


[
view(-6,6,-6,6), Marges(0,0,0,0),
Width:=8, FillStyle:=full, FillColor:=whitesmoke,
{vecteurs de base}
U:=M(2,0,0), V:=M(0,1,0), W:=M(0.25,0.25,1.5),
positions:=[
{couche 1}
3*U, 2*U+V, U+2*V, 2*U+2*V, 3*V, U+3*V,
{couche 2}
2*U+W, U+V+W, 2*V+W,
{couche 3}
U+2*W, U+V+2*W, 2*V+2*W,
{couche 4}
U+3*W, V+3*W,
{couche 5}
4*W],
for A in positions by 2 do Dparallelep(A,U,V,W,1) od
] 


En fait, il s'agit bien de parallélogrammes pavant le plan même si on a une impression d'empilement de cubes.

Sinon, comment hachures-tu une des faces d'un des pavés ?

A l'arrivée on obtiens un pavage pseudo-périodique et non-périodique du plan. Il s'agit d'une généralisation dans le plan d'un découpage sur une droite (qui d'ailleurs me pose aussi problème mais je le posterai demain).

Est-ce toujours la même face que tu veux hachurer?

J'ai fait une macro pour le hachurage, on donne en paramètre le numero de face souhaitée (1=frontale, 2=latérale, 3=supérieure). Pour simplifier j'ai mis A, U, V et W en variables golbales. Je propose ce fichier:

Code:


% TeXgraph version 1.94 beta-7.2
% Fenetre Xmin Xmax Ymin Ymax Xscale Yscale
100#-5#7#-4.5#8#1#1##
% Marges gauche droite haut bas cadre gestion_couleur comptgraph
101#0#0#0#0#0#1#2##
% Affectation des Variables theta et phi et type de perspective
18##[theta:=0.5236, phi:=1.0472,OriginalCoord(1),IdMatrix(),IdMatrix3D(),ModelView(ortho)]##
% Déclaration des Variables Globales
15#A#[0,6]##
15#U#[2,0]##
15#V#[1.5*i,0]##
15#W#[0,1.5]##
% Déclaration des Macros
16#drawPave#{drawPave(num face)}
[SaveAttr(),
 Dparallelep(A,U,V,W,1),
 FillStyle:=diagcross, FillColor:=black, LineStyle:=noline,
 if %1=1 then
    {face avant}
    Ligne3D([A+U,A+U+V,A+U+V+W,A+U+W],1)
 elif %1=2 then
    {face latérale}
    Ligne3D([A+V,A+V+W,A+U+V+W,A+U+V],1)
 elif %1=3 then
    {face supérieure}
    Ligne3D([A+W,A+U+W,A+U+V+W,A+V+W],1)
 fi,
 RestoreAttr()
]##
% Déclaration des Eléments graphiques
% objet1 (Utilisateur)
18##[tMax:=5]##
14#objet1#[
view(-5,7,-4.5,8), Marges(0,0,0,0),
Width:=8, FillStyle:=full, FillColor:=whitesmoke,
{vecteurs de base}
U:=M(2,0,0), V:=M(0,1.5,0), W:=M(0,0,1.5),
{couche 1}
A:=3*U, drawPave(2),
A:=2*U+V, drawPave(),
A:=U+2*V, drawPave(), A:=2*U+2*V, drawPave(),
A:=3*V, drawPave(), A:=U+3*V, drawPave(),
{couche 2}
A:=2*U+W, drawPave(1),
A:=U+V+W, drawPave(),
A:=2*V+W, drawPave(),
{couche 3}
A:=U+2*W, drawPave(),
A:=U+V+2*W, drawPave(2),
A:=2*V+2*W, drawPave(2),
{couche 4}
A:=U+3*W, drawPave(2),
A:=V+3*W, drawPave(2),
{couche 5}
A:=4*W, drawPave(2)
]#-1##


Je suis allé vérifier dans la version anglaise de la première édition l'impression que j'avais avec l'édition russe de la seconde (le papier russe n'est pas d'une grande qualité). En fait, en plus des petit carré que l'on peut rendre avec des hachures, toutes les faces latérales sont grises (ce qui ne se voit vraiment pas bien sur le scan, j'en conviens), les autres étant blanches.

J'ai donc modifié ton code comme suit (j'ai ajouté deux lignes dans la macro)

Code:


% TeXgraph version 1.94 beta-7.2
% Fenetre Xmin Xmax Ymin Ymax Xscale Yscale
100#-4.3#5.5#-4#6.8#0.5#0.5##
% Marges gauche droite haut bas cadre gestion_couleur comptgraph
101#0#0#0#0#0#1#2##
% Affectation des Variables theta et phi et type de perspective
18##[theta:=0.5236, phi:=1.0472,OriginalCoord(1),IdMatrix(),IdMatrix3D(),ModelView(ortho)]##
% Déclaration des Variables Globales
15#A#[0,6]##
15#U#[2,0]##
15#V#[1.5*i,0]##
15#W#[0,1.5]##
% Déclaration des Macros
16#drawPave#{drawPave(num face)}
[SaveAttr(),
 Dparallelep(A,U,V,W,1),
 FillStyle:=full, FillColor:=lightgray,
    Ligne3D([A+V,A+V+W,A+U+V+W,A+U+V],1),
 FillStyle:=diagcross, FillColor:=black, LineStyle:=noline,
 if %1=1 then
    {face avant}
    Ligne3D([A+U,A+U+V,A+U+V+W,A+U+W],1)
 elif %1=2 then
    {face latérale}
    Ligne3D([A+V,A+V+W,A+U+V+W,A+U+V],1)
 elif %1=3 then
    {face supérieure}
    Ligne3D([A+W,A+U+W,A+U+V+W,A+V+W],1)
 fi,
 RestoreAttr()
]##
% Déclaration des Eléments graphiques
% objet1 (Utilisateur)
18##[tMin:=-5,tMax:=5]##
14#objet1#[
view(-4.3,5.5,-4,6.8), Marges(0,0,0,0),
Width:=8, FillStyle:=full, FillColor:=white,
{vecteurs de base}
U:=M(2,0,0), V:=M(0,1.5,0), W:=M(0,0,1.5),
{couche 1}
A:=3*U, drawPave(2),
A:=2*U+V, drawPave(),
A:=U+2*V, drawPave(), A:=2*U+2*V, drawPave(),
A:=3*V, drawPave(), A:=U+3*V, drawPave(),
{couche 2}
A:=2*U+W, drawPave(1),
A:=U+V+W, drawPave(),
A:=2*V+W, drawPave(),
{couche 3}
A:=U+2*W, drawPave(),
A:=U+V+2*W, drawPave(2),
A:=2*V+2*W, drawPave(2),
{couche 4}
A:=U+3*W, drawPave(2),
A:=V+3*W, drawPave(2),
{couche 5}
A:=4*W, drawPave(2)
]#-1##


Encore merci pour ton aide.

Wow!! Très joli ce pavage!!!

Tout ca, ca me fait penser aux pavages de Penrose avec les les gros et petits losanges :


Bon : avec ce dessin on a pas cette impression d'empilement de parallèlépipèdes, mais bon, c'est joli quand même!!!

Merci Cristallo.mod!!!

Salut Eric,

Si tu veux des carrés à la place des hachures comme dans la fgure initiale, remplace le code de la macro drawPave par celui-ci:

Code:


{drawPave(num face)}
[SaveAttr(),
 Dparallelep(A,U,V,W,1),
 FillStyle:=full, FillColor:=darkgray,
    Ligne3D([A+V,A+V+W,A+U+V+W,A+U+V],1),
 FillStyle:=none, $F:=Nil,
 if %1=1 then {face avant}
    F:=[A+U,A+U+V,A+U+V+W,A+U+W],
 elif %1=2 then {face latérale}
    F:=[A+V,A+V+W,A+U+V+W,A+U+V]
 elif %1=3 then {face supérieure}
    F:=[A+W,A+U+W,A+U+V+W,A+V+W]
 fi,
 Ligne3D(hom3d(F,isobar3d(F),0.5),1),
 RestoreAttr()
]


Salut Alphonse!

Je me disais bien aussi! Je n'ai pas parlé de cristallo.mod hier car je ne suis pas bien sûr qu'il y ait le pavage que cherche à faire Eric.

En regardant de près ton image, j'ai quand même l'impression d'un empilement de parallélépièdes, mais contrairement au dessin d'Eric, où il s'agit toujours du même qui est translaté, j'y vois plusieurs parallélépipèdes différents agencés d'une certaine façon qui me semble régulière, mais bon j'ai peut-être la berlue

Edit: bon, en y regardant d'encore plus près, je crois bien que j'ai la berlue finalement. Faut dire aussi que l'heure de l'apéro approche

J'ai modifié la macro suivant tes instructions et ça roule pile-poil !