section

Bonsoir, dernière question de la soirée :
Dans le code :

Code:

[
Plan:=[M(2,2,0),vecJ+vecK],
Pave:=Parallelep(Origin,2*vecI,3*vecJ,vecK,0),
povScene(
  povLine(Pave,[color:=red,tube:=1]),
  povPlan(Plan,[scale:=1,border:=1, bordercolor:=black, tube:=1, opacity:=0.75]),
),
Display3D()
]

J'ai essayé d'utiliser la macro Intersection pour faire apparaitre la section de ce pave avec le plan, avec le code :

Code:

L:=Intersection(Pave,Plan),
povLine(Merge3d([L])

Mais je n'obtiens rien

Merci

Bonjour Joffrey,

Tu n'étais pas loin! La syntaxe de la macro Intersection est: Intersection( plan, polyedre )
Tu dois donc mettre: L := Intersection(Plan,Pave).

Juste une remarque: pourquoi mettre toutes les arêtes en tube? Cela alourdit l'image (tube=plein de facettes). Personnellement j'aurais dessiner le pavé plein avec de la transparence pour voir la partie cachée de la section, comme ceci:

Code:


[
Plan:=[M(2,2,0),vecJ+vecK],
Pave:=Parallelep(Origin,2*vecI,3*vecJ,vecK,0),
L:=Intersection(Plan,Pave),
povScene(
  povPlan(Plan,[scale:=0.75,border:=1, bordercolor:=black, tube:=0, opacity:=0.75]),
  povFacet(Pave,[color:=red,tube:=0, shadow:=0, opacity:=0.6]),
  povLine(Merge3d(Aretes(Pave)), [color:=black, shadow:=0,]),
  povLine(Merge3d([L]))
),
Display3D()
] 


Pour changer, voici l'export svg du dessin, celui-ci est vectoriel, bien adapté aux pages web, et on peut l'utiliser dans ce forum si vous avez activé l'html dans votre profil

Code:


<object type="image/svg+xml" data="http://www.fileupyours.com/view/162411/section.svg" width="400" height="400">
Le navigateur ne supporte pas les fichiers SVG !
</object>


PS: je réfléchis au problème des patrons.

Ah zut!! Tu as été plus rapide que moi pour la réponse concernant la section de polyèdre!!!

Concernant les patrons de polyèdres, merci de ton aide!!!

Bonjour, merci pour la réponse.
J'étais pourtant sûr d'avoir essayé aussi Intersection(Plan,Pave) je l'avais lu dans TeXgraph.mac.
Merci et bonne journée.

Salut tout le monde,
Est-il possible d'avoir les parties cachées en pointillés ?
De même est-il possible de représenter des plans (sécants ou non) où les parties cachées d'un plan par un autre seraient en pointillés ?
Merci

Bonsoir Jean-François,

Oui c'est possible! Mais pas dans la scène 3D, il faut redessiner les différentes arêtes concernées, en pointillés et par dessus la scène, c'est ça l'astuce. Par contre ces pointillés n'apparaîtront pas dans l'export povray (ni javaview, ni obj, ni geom) mais dans les exports classiques. En reprenant l'exemple de section donné par Joffrey:

Code:


[
Plan1:=[M(2,2,0),vecJ+vecK],
Plan2:=[M(2,2,0),vecI+vecK],
Pave:=Parallelep(Origin,3*vecI,3*vecJ,4*vecK,0),
L1:=Merge3d(Intersection(Plan1,Pave)),
L2:=Merge3d(Intersection(Plan2,Pave)),
A:=Merge3d(Aretes(Pave)),
povScene(
  povPlan(Plan1,[color:=slategray,scale:=0.75,border:=1, bordercolor:=black]),
  povPlan(Plan2,[color:=lightgray,scale:=0.75, border:=1, bordercolor:=black]),
  povFacet(Pave,[color:=red, shadow:=0]),
  povLine(A, [color:=black, shadow:=0,]),
  povLine([L1,L2])
),
Display3D(),
{maintenant on dessine par dessus la scène}
Width:=8, LineStyle:=dotted,
Ligne3D(getplan(Plan1,0.75),1), Ligne3D(getplan(Plan2,0.75),1), Ligne3D(A,1),
Ligne3D([L1,jump,L2],0)
]


Dans l'aperçu on obtient ça:


mais dans l'export povray on ne voit pas les pointillés.

Bonsoir Patrick,
C'est impeccable et je m'en sert pour un export pgf donc pas de problème.
Merci encore.

Bonsoir,
Je suis toujours avec mes sections. J'aurais voulu créer une animation pour la section d'un parallélépipède rectangle; à l'image d'un couteau qui coupe une plaquette de beurre (attention au cholestérol ) j'aurais voulu représenter mon plan comme s'il descendait.
J'ai essayé en faisant varier les coordonnées du point du plan que je voulais représenter sans succès; j'ai aussi essayé getplan sans réussite.
Comme tu verras dans mon code, je me suis rabattu à faire varier theta, aurais-tu une idée?

Code:


% TeXgraph version 1.94 beta-8.2
% Fenetre Xmin Xmax Ymin Ymax Xscale Yscale
100#-5#5#-5#5#1#1##
% Marges gauche droite haut bas cadre gestion_couleur comptgraph
101#0.5#0.5#0.5#0.5#0#1#3##
% Affectation des Variables theta et phi et type de perspective
18##[theta:=0.9599, phi:=0.9599,OriginalCoord(1),IdMatrix(),IdMatrix3D(),
ModelView(ortho)]##
% Déclaration des Variables Globales
15#povrayver#0.5##
15#povrayload#InputMac("povray.mac")##
15#theta1#55##
15#y#0##
% Déclaration des Macros
16#povparam#"+A +P +FN"##
16#animparam#"+A +FN"##
16#povIncludePath#if Windows then "+L'c:\Program Files\povray\include'" else "" fi##
16#beginAnim#[{mettre ici le code à exécuter avant l'animation}
theta:=theta1*deg, phi:=65*deg, y:=-5,
]##
16#endAnim#[{mettre ici le code à exécuter après l'animation}
ReCalc()
]##
16#povFrame#[{Entrer ici le code pour construire la frame numéro %1 de l'animation}
{if %1>1 then
        Inc(y,1),
        ReCalc(objet1)
fi}
if %1>1 then
        Inc(theta1,5),
        ReCalc(vue)
fi,

]##
16#GlobalSettings#["global_settings { charset utf8",LF,
 "                  ambient_light rgb 1.5",LF,
 "}"]##
16#IncludeFiles#1/0##
16#Init#[$x:=0,
Bouton(RefPoint,"Paramètres povray","defParam()","Modifier les paramètres pour povray"),
Inc(x,DeltaB),
Bouton(RefPoint+x,"Export povray",
                "defNomExport()",
                "Exporter la scene3D en un fichier *.pov pour povray"),
Inc(x,DeltaB),
Bouton(RefPoint+x,"Animation povray",
                "defAnim()",
                "Exporter une série de fichiers *.pov pour povray")
]##
16#NomExport#"image"##
16#povsize#"+W640 +H640"##
16#renduPov#"object{ objet1
        pigment{ color rgb<1,0,0>}
        finish{ ambient 0.35  diffuse 0.8 phong 0.5}
    }
object{ objet2
        pigment{ color rgb<1,0,0> transmit 0.5}
        finish{ ambient 0.35  diffuse 0.8 }
    }
object{ objet3
        pigment{ color rgb<0.82745098039215,0.82745098039215,0.82745098039215> transmit 0.5}
        finish{ ambient 0.35  diffuse 0.8 }
    }
object{ objet4
        pigment{ color rgb<0,0,0> transmit 0.5}
        finish{ ambient 0.35  diffuse 0.8 phong 0.5}
    }
object{ objet5
        pigment{ color rgb<0,0,0>}
        finish{ ambient 0.35  diffuse 0.8 phong 0.5}
    }
"##
% Déclaration des Eléments graphiques
% objet1 (Utilisateur)
18##[DotScale:=1+i]##
14#objet1#[
A:=M(0,y,3-y),
Plan:=[A,-vecJ-vecK],
Pave:=Parallelep(M(-2,0,0),4*vecI,5*vecJ,2*vecK,0),
L:=Intersection(Plan,Pave),
povScene(
  povLine(Pave,[color:=red]),
  povFacet(Pave,[color:=red,opacity:=0.5]),
  povPlan(Plan,[scale:=0.75,border:=1, bordercolor:=black,
                opacity:=0.5,color:=lightgray]),
  povLine(L)
),
Display3D(),
]#
-1##
% axes3D2 (Utilisateur)
18##[IsVisible:=0]##
14#axes3D2#Axes3D(0,0,0,1,1,1)#
-1##
% vue (Utilisateur)
18##[IsVisible:=1]##
14#vue#[
theta:=theta1*deg, phi:=55*deg
]#
-1##


Bonne soirée

Bonsoir Joffrey,

Voici une proposition où je remplace le plan par une facette que l'on translate à chaque frame, voici le fichier source: sectionPave.teg. Je te laisse regarder le code, si tu veux des éclaircissements n'hésite pas. Et l'animation obtenue:



C'est bien ce que tu cherchais à faire?

Bonjour,
je viens de ragrder ton animation c'est tout a fait ce dont je voulais, je regarde le code ce soir, je n'hésiterais pas à demander des eclaircissements.

Bonne journée