"Construction" papiers classiques

Voir le sujet précédent Voir le sujet suivant Aller en bas

"Construction" papiers classiques

Message  Joffrey le Jeu 18 Déc - 0:31

Bonsoir,

Je viens de terminer un petit fichier permettant d'obtenir simplement des papiers classiques :
- papier millimétré
- papier petit carreau
- papier grand carreau
- papier pointé de trois types.
Les dimensions largeur et hauteur sont initialisées à 10, elles sont modifiables dans la parties variables globales.

PapiersClassiques.teg
Code:
% TeXgraph version 1.94 beta-7.3
% Fenetre Xmin Xmax Ymin Ymax Xscale Yscale
100#0#10#0#10#1#1##
% Marges gauche droite haut bas cadre gestion_couleur comptgraph
101#0.5#0.5#0.5#0.5#0#1#8##
% Affectation des Variables theta et phi et type de perspective
18##[theta:=0.5236, phi:=1.0472,OriginalCoord(1),IdMatrix(),IdMatrix3D(),ModelView(ortho)]##
% Déclaration des Variables Globales
15#largeur#10##
15#hauteur#10##
15#gridcolor#black##
15#subgridcolor#Rgb(0.66,0.66,0.5)##
% Déclaration des Macros
16#Init#[$x:=0,
Bouton( RefPoint+x, "Papier millimetre",
        "[Hide(), Show(papiermilli), ReCalc(papiermilli),]",
        "Papier millimetre (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier petit carreaux",
        "[Hide(), Show(pt_carreau), ReCalc(pt_carreau),]",
        "Papier petit carreau (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier grand carreau",
        "[Hide(), Show(gd_carreau), ReCalc(gd_carreau),]",
        "Papier petit carreau (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier pointe type 1",
        "[Hide(), Show(papierpointetype1), ReCalc(papierpointetype1),]",
        "Papier pointe type 1 (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier pointe type 2",
        "[Hide(), Show(papierpointetype2), ReCalc(papierpointetype2),]",
        "Papier pointe type 2 (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier pointe type 3",
        "[Hide(), Show(papierpointetype3), ReCalc(papierpointetype3),]",
        "Papier pointe type 3 (l*L)"), Inc(x,DeltaB),
]##
% Déclaration des Eléments graphiques
% papiermilli (Utilisateur)
18##[IsVisible:=0,tMin:=-5,tMax:=5]##
14#papiermilli#[
view(0,largeur,0,hauteur),
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur*i,1+i),

Width:=2,
{subgrid}
Color:=subgridcolor,
Ligne( [for k from 0 to largeur step 0.1 do  k , k+hauteur*i , jump od],0),
Ligne( [for k from 0 to hauteur step 0.1 do  k*i , largeur+k*i , jump od],0),
{grid}
Color:=gridcolor,
Ligne( [for k from 0 to largeur step 0.5 do k , k+hauteur*i , jump od],0),
Ligne( [for k from 0 to hauteur step 0.5 do k*i , largeur+k*i , jump od],0),
]#-1##
% pt_carreau (Utilisateur)
18##[tMin:=0,tMax:=3]##
14#pt_carreau#[
view(0,largeur,0,hauteur),
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur*i,1+i),

Width:=2,
{subgrid}
Color:=subgridcolor,
Ligne( [for k from 0 to largeur step 0.5 do  k , k+hauteur*i , jump od],0),
Ligne( [for k from 0 to hauteur step 0.5 do  k*i , largeur+k*i , jump od],0),
{grid}
Color:=gridcolor,
Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od],0),
Ligne( [for k from 0 to hauteur do k*i , largeur+k*i , jump od],0),
]#-1##
% gd_carreau (Utilisateur)
14#gd_carreau#[
view(0,largeur,0,hauteur),
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur*i, 1+i),

Width:=2,
{subgrid}
Color:=subgridcolor,
Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od],0),
Ligne( [for k from 0 to hauteur step 0.25 do  k*i , largeur+k*i , jump od],0),
{grid}
Color:=gridcolor,
Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od],0),
Ligne( [for k from 0 to hauteur do k*i , largeur+k*i , jump od],0),

]#-1##
% papierpointetype1 (Utilisateur)
18##[tMax:=10]##
14#papierpointetype1#[
view(0,largeur,0,hauteur),
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur*i,1+i),

Width:=2,

for k from 0 to largeur step 0.5 do
  for z from 0 to hauteur step 0.5 do Point(k+z*i)
  od,
od,
]#-1##
% papierpointetype2 (Utilisateur)
14#papierpointetype2#[
view(0,largeur,0,hauteur),
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur*i,1+i),

Width:=2,

for k from 0 to largeur step 1 do
  for z from 0 to hauteur step 1 do Point(k+z*i)
  od,
od,
]#-1##
% papierpointetype3 (Utilisateur)
14#papierpointetype3#[
view(0,largeur,0,hauteur),
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur*i,1+i),

Width:=2,

for z from 0 to hauteur do
  for k from 0 to largeur do Point(k+z*i)
  od,
od,

for z from 0.5 to hauteur-0.5 do
  for k from 0+.5 to largeur-0.5 do Point(k+z*i)
  od,
od,
]#-1##

Bonne soirée

Joffrey

Joffrey

Nombre de messages : 179
Age : 35
Localisation : Vichy(03) / Clermont-Ferrand(63)
Date d'inscription : 13/06/2008

Voir le profil de l'utilisateur http://mathex.servhome.org

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Jeu 18 Déc - 1:17

Bonsoir Joffrey,

C'est une bonne idée, il n'y avait rien de prévu pour cela. J'ai testé ton code et j'ai corrigé deux ou trois bricoles:

-> comme tu utilises la commande Fenetre, il est inutile d'utiliser view() avant. Dans la commande Fenetre on met le coin sup gauche et le coin inf droit.

-> plutôt que de faire un élément Point pour chaque point, on peut faire un seul élément Point avec une liste de points (idem pour les lignes).

Code:

% TeXgraph version 1.94 beta-7.3
% Fenetre Xmin Xmax Ymin Ymax Xscale Yscale
100#0#10#0#10#1#1##
% Marges gauche droite haut bas cadre gestion_couleur comptgraph
101#0.5#0.5#0.5#0.5#0#1#8##
% Affectation des Variables theta et phi et type de perspective
18##[theta:=0.5236, phi:=1.0472,OriginalCoord(1),IdMatrix(),IdMatrix3D(),
ModelView(ortho)]##
% Déclaration des Variables Globales
15#largeur#10##
15#hauteur#10##
15#gridcolor#black##
15#subgridcolor#Rgb(0.66,0.66,0.5)##
% Déclaration des Macros
16#Init#[$x:=0,
Bouton( RefPoint+x, "Papier millimetre",
        "[Hide(), Show(papiermilli), ReCalc(papiermilli)]",
        "Papier millimetre (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier petit carreaux",
        "[Hide(), Show(pt_carreau), ReCalc(pt_carreau)]",
        "Papier petit carreau (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier grand carreau",
        "[Hide(), Show(gd_carreau), ReCalc(gd_carreau)]",
        "Papier petit carreau (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier pointe type 1",
        "[Hide(), Show(papierpointetype1), ReCalc(papierpointetype1)]",
        "Papier pointe type 1 (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier pointe type 2",
        "[Hide(), Show(papierpointetype2), ReCalc(papierpointetype2)]",
        "Papier pointe type 2 (l*L)"), Inc(x,DeltaB),
Bouton( RefPoint+x, "Papier pointe type 3",
        "[Hide(), Show(papierpointetype3), ReCalc(papierpointetype3)]",
        "Papier pointe type 3 (l*L)"), Inc(x,DeltaB),
]##
% Déclaration des Eléments graphiques
% papiermilli (Utilisateur)
18##[IsVisible:=0,tMin:=-5,tMax:=5]##
14#papiermilli#[
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur,1+i),

Width:=2,
{subgrid}
Color:=subgridcolor,
Ligne( [for k from 0 to largeur step 0.1 do  k , k+hauteur*i , jump od,
        for k from 0 to hauteur step 0.1 do  k*i , largeur+k*i , jump od
      ],0),
{grid}
Color:=gridcolor,
Ligne( [for k from 0 to largeur step 0.5 do k , k+hauteur*i , jump od,
        for k from 0 to hauteur step 0.5 do k*i , largeur+k*i , jump od
      ],0),
]#
-1##
% pt_carreau (Utilisateur)
18##[tMin:=0,tMax:=3]##
14#pt_carreau#[
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur,1+i),

Width:=2,
{subgrid}
Color:=subgridcolor,
Ligne( [for k from 0 to largeur step 0.5 do  k , k+hauteur*i , jump od,
        for k from 0 to hauteur step 0.5 do  k*i , largeur+k*i , jump od
      ],0),
{grid}
Color:=gridcolor,
Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od,
        for k from 0 to hauteur do k*i , largeur+k*i , jump od
      ],0),
]#
-1##
% gd_carreau (Utilisateur)
14#gd_carreau#[
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur, 1+i),

Width:=2,
{subgrid}
Color:=subgridcolor,
Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od,
        for k from 0 to hauteur step 0.25 do  k*i , largeur+k*i , jump od
      ],0),
{grid}
Color:=gridcolor,
Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od,
        for k from 0 to hauteur do k*i , largeur+k*i , jump od
      ],0),

]#
-1##
% papierpointetype1 (Utilisateur)
18##[tMax:=10]##
14#papierpointetype1#[
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur,1+i),

Width:=2,

Point(
 for k from 0 to largeur step 0.5 do
  for z from 0 to hauteur step 0.5 do k+z*i
  od,
 od)
]#
-1##
% papierpointetype2 (Utilisateur)
14#papierpointetype2#[
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur,1+i),

Width:=2,

Point(
 for k from 0 to largeur step 1 do
  for z from 0 to hauteur step 1 do k+z*i
  od,
 od)
]#
-1##
% papierpointetype3 (Utilisateur)
18##[IsVisible:=1]##
14#papierpointetype3#[
Marges(0.5,0.5,0.5,0.5),
Fenetre(hauteur*i,largeur,1+i),

Width:=2,



Point(
 [for z from 0 to hauteur do
  for k from 0 to largeur do k+z*i
  od,
  od,
 for z from 0.5 to hauteur-0.5 do
  for k from 0+.5 to largeur-0.5 do k+z*i
  od,
 od]),
]#
-1##

Je peux te proposer de mettre ton fichier avec les contributions, ou alors on en fait un fichier de macros *.mac et le modèle *.mod qui va avec. Dans le fichier *.mac on ne met que les macros qui font le dessin et les variables globales (ce fichier est alors utilisable directement dans un document LateX), et dans le fichier mod on créé le menu comme tu as fait.

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  Joffrey le Jeu 18 Déc - 21:34

Bonsoir,

P.Fradin a écrit :
-> comme tu utilises la commande Fenetre, il est inutile d'utiliser view() avant. Dans la commande Fenetre on met le coin sup gauche et le coin inf droit.

Ce qui explique pourquoi j'avais un souci d'echelle

-> plutôt que de faire un élément Point pour chaque point, on peut faire un seul élément Point avec une liste de points (idem pour les lignes).

Je l'ai fait pour Ligne, je ne sais pas pourquoi je ne l'ai pas fait pour Point, on va coller ça sur le dos de la fatigue.

Je peux te proposer de mettre ton fichier avec les contributions, ou alors on en fait un fichier de macros *.mac et le modèle *.mod qui va avec.

Sans problème, personnellement je pense qu'un fichier de macros regroupant tous les types de papiers peut être plus pratique. Par contre pour le fichier .mod qui va avec, je ne sais pas trop comment il se construit et à quoi il sert.

Je peux m'occuper de regrouper tous les styles de papiers si ça t'arrange.

Joffrey

Joffrey

Nombre de messages : 179
Age : 35
Localisation : Vichy(03) / Clermont-Ferrand(63)
Date d'inscription : 13/06/2008

Voir le profil de l'utilisateur http://mathex.servhome.org

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Jeu 18 Déc - 22:39

Joffrey a écrit:Bonsoir,

Bonsoir Joffrey


Je peux m'occuper de regrouper tous les styles de papiers si ça t'arrange.

C'est à dire? Je pensais simplement faire un petit fichier *.mac qui contiendrait essentiellement une macro du genre: papier(type, coin inf gauche, coin sup droit <, options>) et qui ferait le dessin des cinq types de papiers que tu proposes. Quant au fichier *.mod, il aurait pour rôle de charger le fichier *.mac et d'afficher un menu dans l'interface graphique.

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  Jean-François le Jeu 18 Déc - 23:46

Bonsoir Patrick et Joffrey,

Très pratique ces différents types de papiers.
Je pensais simplement faire un petit fichier *.mac qui contiendrait essentiellement une macro du genre: papier(type, coin inf gauche, coin sup droit <, options>) et qui ferait le dessin des cinq types de papiers que tu proposes.
Très bonne idée si je puis me permettre (a priori c'est plus fonctionnel mais ce n'est que mon avis).
Merci à vous deux pour ce travail.

Jean-François

Nombre de messages : 38
Age : 43
Date d'inscription : 19/11/2008

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Jeu 18 Déc - 23:57

Bonsoir Jean-François,

Aussitôt dit, aussitôt fait! Voici une proposition pour papiers.mac:

Code:

200#
{papiers.mac version 0.1 du 18/12/08 Joffrey Cottin}

Var papiersvernum = 0.1;
    gridcolor = black;
    subgridcolor = Rgb(0.66,0.66,0.5);
    milli = 0;
    petitcar = 1;
    grandcar = 2;
    point1  =  3;
    point2  =  4;
    point3  =  5;

Mac

    papier = [{papier( type, coin inf gauche, coin sup droit <, options>)
      options:
      gridcolor := <couleur> (black par défaut)
      subgridcolor := <couleur> (Rgb(0.66,0.66,0.5) par défaut)
      ou attributs classiques comme Width:= ,...
                }

   $type:=%1, $x1:=%1, $x2:=%3, gridcolor:=black, subgridcolor:= Rgb(0.66,0.66,0.5), Width:=2,
   $aux:=Eval(String(%4)), SaveAttr(), SetMatrix([%2,1/Xscale,i/Yscale]),
   $x1:=Re(%2), $x2:=Re(%3), $y1:=Im(%2), $y2:=Im(%3), $largeur:=(x2-x1)*Xscale, $hauteur:=(y2-y1)*Yscale,
   if type=milli then
      {subgrid}
      Color:=subgridcolor,
      Ligne( [for $k from 0 to largeur step 0.1 do  k , k+hauteur*i , jump od,
              for k from 0 to hauteur step 0.1 do  k*i , largeur+k*i , jump od
               ],0),
      {grid}
      Color:=gridcolor,
      Ligne( [for k from 0 to largeur step 0.5 do k , k+hauteur*i , jump od,
              for k from 0 to hauteur step 0.5 do k*i , largeur+k*i , jump od
               ],0)
   elif type=petitcar then
      {subgrid}
      Color:=subgridcolor,
      Ligne( [for k from 0 to largeur step 0.5 do  k , k+hauteur*i , jump od,
              for k from 0 to hauteur step 0.5 do  k*i , largeur+k*i , jump od
                  ],0),
      {grid}
      Color:=gridcolor,
      Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od,
              for k from 0 to hauteur do k*i , largeur+k*i , jump od
               ],0)
   elif type=grandcar then
      {subgrid}
      Color:=subgridcolor,
      Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od,
              for k from 0 to hauteur step 0.25 do  k*i , largeur+k*i , jump od
            ],0),
      {grid}
      Color:=gridcolor,
      Ligne( [for k from 0 to largeur do k , k+hauteur*i , jump od,
              for k from 0 to hauteur do k*i , largeur+k*i , jump od
               ],0),
   elif type=point1 then
      Point( for k from 0 to largeur step 0.5 do
              for $z from 0 to hauteur step 0.5 do k+z*i od
          od),
   elif type=point2 then
      Point( for k from 0 to largeur step 1 do
              for z from 0 to hauteur step 1 do k+z*i od,
          od),
   elif type=point3 then
      Point( [for z from 0 to hauteur do
              for k from 0 to largeur do k+z*i  od
           od,
          for z from 0.5 to hauteur-0.5 do
              for k from 0+.5 to largeur-0.5 do k+z*i od,
          od])
   fi,
   RestoreAttr()];

il n'y a qu'une macro: papier( type, coin inf gauche, coin sup droit <,options>) avec:

type= milli ou petitcar ou grandcar ou point1 ou point2 ou point3, et les options:
gridcolor := (black par défaut)
subgridcolor := (Rgb(0.66,0.66,0.5) par défaut)

à noter également que dans les options on peut modifier les attributs comme Width, LineStyle, ...

Plutôt que de faire un fichier modèle avec un menu, je propose d'ajouter l'option papiers dans le menu Créer/Autres éléments 2D, qu'en pensez-vous?

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  Jean-François le Ven 19 Déc - 0:13

Re,
Aussitôt dit, aussitôt fait!
Encore une fois, quelle efficacité !
Plutôt que de faire un fichier modèle avec un menu, je propose d'ajouter l'option papiers dans le menu Créer/Autres éléments 2D, qu'en pensez-vous?
Bonne idée pour ma part.

Jean-François

Nombre de messages : 38
Age : 43
Date d'inscription : 19/11/2008

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Ven 19 Déc - 0:23

Jean-François a écrit:
Encore une fois, quelle efficacité !

Merci, mais j'y avais déjà réfléchi avant d'en parler, c'est pour ça!


Plutôt que de faire un fichier modèle avec un menu, je propose d'ajouter l'option papiers dans le menu Créer/Autres éléments 2D, qu'en pensez-vous?
Bonne idée pour ma part.

Pour ajouter cette option, il faut déjà enregistrer papiers.mac dans un dossier connu de TeXgraph (le dossier macros ou le dossier $HOME/TeXgraphMac sous linux ou le dossier contenu dans la variable d'environnement TeXgraphMac si vous l'avez créé sous windows). Une fois ceci fait, il faut éditer le fichier interface.mac (attention il est en utf8 dans la dernière version) et on ajoute ceci:

Code:

102#papiers'#
if Input(" Dessine un papier quadrillé

 type est une des six valeurs: milli ou petitcar ou grandcar ou point1 ou point2 ou point3
 coin inf gauche: affixe du coin inférieur gauche,
 coin sup droit: affixe du coin supérieur droit,
 options: liste facultative d'affectations qui peuvent être:
  gridcolor := couleur (black par défaut)
  subgridcolor := couleur (Rgb(0.66,0.66,0.5) par défaut)

Exemple: milli, M(-5,-5), M(5,5) ", " papier( type, coin inf gauche, coin sup droit <,[option]>)",chaine())
then
Inc(ComptGraph,1),
InputMac("papiers.mac"),
NewGraph(["papier",ComptGraph],["papier(", chaine(), "){nécessite papiers.mac}"]), ReDraw()
fi#Différents papiers quadrillés##

Attention: pas d'espace après les deuxs symboles ##

On sauve, et au prochain lancement de TeXgraph l'option sera ajoutée.

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  Joffrey le Ven 19 Déc - 22:01

Bonsoir,

je remarque que j'arrive après la bataille!

Néanmoins, j'ai essayé cette nouvelle macro, c'est bien dans le menu déroulant.

Juste une petite chose, pour les personnes qui travaille sous Windows, le bloc note n'est pas du tout pratique pour faire les modifications. Lorsque l'on ouvre une macro avec cet utilitaire, on obtient de nombreuses lignes de code, sans espace ni retour à la ligne. J'ai (ré-)opté pour notepad++ qui permet d'avoir un code lisible à l'écran saut de ligne, espaces, ...).

Penses-tu qu'il faut que je fasse un petit document expliquant les différent papiers (point1, point2 et point3)?


Joffrey

Joffrey

Nombre de messages : 179
Age : 35
Localisation : Vichy(03) / Clermont-Ferrand(63)
Date d'inscription : 13/06/2008

Voir le profil de l'utilisateur http://mathex.servhome.org

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Ven 19 Déc - 22:47

Joffrey a écrit:Bonsoir,

Bonsoir Joffrey,


Juste une petite chose, pour les personnes qui travaille sous Windows, le bloc note n'est pas du tout pratique pour faire les modifications. Lorsque l'on ouvre une macro avec cet utilitaire, on obtient de nombreuses lignes de code, sans espace ni retour à la ligne. J'ai (ré-)opté pour notepad++ qui permet d'avoir un code lisible à l'écran saut de ligne, espaces, ...).

Désormais tout est en utf8 sous windows également. notepad++ est effectivement bien plus adapté, non seulement il reconnait les différents encodages possibles mais il reconnait aussi les différentes fins de lignes. C'est un éditeur "intelligent", il permet aussi la coloration syntaxique.

Ceci dit, il est possible d'éditer un fichier directement dans TeXgraph avec l'option Edition/Editer un texte, une fenêtre s'ouvre avec un menu minimaliste mais suffisant pour ouvrir et éditer/modifier un fichier texte avec la coloration teg, la coloration TeX ou sans coloration.


Penses-tu qu'il faut que je fasse un petit document expliquant les différent papiers (point1, point2 et point3)?

Bof, je ne pense pas que cela soit indispensable pour le moment. Peut-être que si ce fichier venait à s'étoffer davantage il faudrait envisager une doc.

Je crée un fil dans la rubrique "Macros à télécharger" pour ce fichier, on pourra continuer la discussion sur cet autre fil.

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  toumouye le Dim 26 Avr - 19:09

Bonjour,

J'ai mis le fichier papiers.mac dans le répertoire macros et tout fonctionne avec l'interface graphique de Texgraph.

papier(milli,-1-i,1+i) me donne ce que je veux.

Je me demande comment je pourrais utiliser l'instruction (ou macro ?) "papier" au sein d'un environnement Texgraph.

J'ai essayé le code suivant :

Code:

\begin{texgraph}[file]
Include "papiers.mac";
Cmd[Fenetre(-2.5+3*i,3.5-4.5*i,1+i),Marges(0,0,0,0),
    papier(milli,-1-i,1+i)
   ];
\end{texgraph}

mais cela ne fonctionne pas.

De même, le code

Code:

\begin{texgraph}
Fenetre(-2.5+3*i,3.5-4.5*i,1+i),Marges(0,0,0,0),
    papier(milli,-1-i,1+i)
\end{texgraph}

ne donne rien non plus.

toumouye

Nombre de messages : 40
Age : 41
Date d'inscription : 13/10/2008

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  toumouye le Dim 26 Avr - 19:14

J'imagine qu'il y a un truc à faire avec un fichier .mod, mais je ne comprends pas comment il est construit.

toumouye

Nombre de messages : 40
Age : 41
Date d'inscription : 13/10/2008

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  toumouye le Dim 26 Avr - 21:32

Autre chose que je ne comprends pas. Lorsque je lance texgraph, si je fais fichier / importer macro puis "papiers.mac",
un ctrl+u avec [papier(milli,-1-i,1+i)], me trace un papier millimétré. OK.

Si j'ouvre texgraph, que je fais ctrl+u puis [InputMac("papiers.mac"),papier(milli,-1-i,1+i)], cela ne donne rien.

toumouye

Nombre de messages : 40
Age : 41
Date d'inscription : 13/10/2008

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Dim 26 Avr - 21:38

Bonjour toumouye,

Chez moi ce code fonctionne:

Code:

\begin{texgraph}[file]
Include "papiers.mac";
Cmd  Fenetre(-2.5+3*i,3.5-4.5*i,1+i);
     Marges(0,0,0,0);
Graph image = papier(milli,-1-i,1+i);
\end{texgraph}

Il faut pour cela que le fichier papiers.mac soit dans un dossier connu de TeXgraph (lire le texte papiers.txt à ce sujet).

La rubrique Graph annonce un (ou des) élément graphique utililsateur (de la forme nom = commande; ).

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Dim 26 Avr - 21:47

toumouye a écrit:
Si j'ouvre texgraph, que je fais ctrl+u puis [InputMac("papiers.mac"),papier(milli,-1-i,1+i)], cela ne donne rien.

La raison est un peu technique: TeXgraph lit la liste (=commande) jusqu'au bout avant de commencer à l'exécuter, donc lorsque TeXgraph lit le nom papier, celle-ci n'est pas encore chargée et donc la macro "pointe sur rien" et rien ne se passe (à part le chargement du fichier), mais si tu fais F10, le recalcul de la commande donnera bien le graphique attendu.

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  toumouye le Dim 26 Avr - 22:09

Merci pour cette réponse rapide qui me permet de faire ce que je voulais. Il me reste une question "technique" :

Quelle est la différence entre les codes suivants ? (étant donné qu'ils produisent le même résultat)

Code:

\begin{texgraph}[file]
Include "papiers.mac";
Cmd  Fenetre(-2.5+3*i,3.5-4.5*i,1+i);
    Marges(0,0,0,0);
Graph image = papier(milli,-1-i,1+i);
\end{texgraph}

Code:

\begin{texgraph}[file]
Include "papiers.mac";
Graph image = [
Fenetre(-2.5+3*i,3.5-4.5*i,1+i),Marges(0,0,0,0),
papier(milli,-1-i,1+i)
];
\end{texgraph}

toumouye

Nombre de messages : 40
Age : 41
Date d'inscription : 13/10/2008

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  P.Fradin le Dim 26 Avr - 22:21

Il n'y en a pas! Les commandes Fenetre et Marges ne font pas véritablement de "dessin", mais peuvent néanmoins être utilisées dans la définition d'un élément graphique (comme la plupart des commandes d'ailleurs). Par contre, les commandes qui font un dessin, n'ont d'effet que dans la rubrique Graph.

_________________
P.Fradin

P.Fradin
Admin

Nombre de messages : 1133
Age : 55
Date d'inscription : 19/01/2008

Voir le profil de l'utilisateur http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  toumouye le Dim 26 Avr - 23:01

OK !

toumouye

Nombre de messages : 40
Age : 41
Date d'inscription : 13/10/2008

Voir le profil de l'utilisateur

Revenir en haut Aller en bas

Re: "Construction" papiers classiques

Message  Contenu sponsorisé Aujourd'hui à 5:59


Contenu sponsorisé


Revenir en haut Aller en bas

Voir le sujet précédent Voir le sujet suivant Revenir en haut

- Sujets similaires

 
Permission de ce forum:
Vous ne pouvez pas répondre aux sujets dans ce forum