TeXgraph
Vous souhaitez réagir à ce message ? Créez un compte en quelques clics ou connectez-vous pour continuer.
Le deal à ne pas rater :
Google Pixel 7 5G – Smartphone 6,3″ OLED FHD+ 8 Go + 128 Go
316 €
Voir le deal

Empilement de boules

5 participants

Page 1 sur 2 1, 2  Suivant

Aller en bas

Empilement de boules Empty Empilement de boules

Message  F.Couvreur Lun 3 Nov - 14:26

Bonjour Patrick,
Je prépare pour mes élèves de seconde un dns avec un exercice d'empilement de boules.
Je veux illustrer cet exercice avec une figure dont voici le code :
Code:
[view3D(-8,8,-8,8,-6,6),Marges(0,0,0,0),
  S1:=Sphere([0-2*i,0],2,25,25),
  S2:=shift3d(S1,4*vecJ),
  S3:=shift3d(S1,2*vecJ+4*vecI),
  S4:=Sphere([(1/3)+0*i,2*sqrt(3)],2,25,25),
  P:=[M(0,0,-2),vecK],
  Build3D(bdFacet(S1, [color:=red, gouraud:=1]),
          bdFacet(S2, [color:=steelblue, gouraud:=1]),
          bdFacet(S3, [color:=yellow, gouraud:=1]),
          bdFacet(S4, [color:=green, gouraud:=1]),
          bdPlan(P,[color:=ivory,opacity:=0,75,scale=1])),
  Display3D()] 
J'ai plusieurs problèmes :
- je ne parviens pas à modifier phi et theta pour avoir la boule du dessus tangente aux trois autres sans avoir des bugs ! (j'ai un vieux coucou !) ;
- j'aimerais que le plan sur lequel repose les quatre boules ait la forme d'un parallélogramme avec le contour dessiné ;
- je ne parviens pas à dessiner une flèche avec la commande Ligne3D pour indiquer la hauteur h de l'empilement (la flèche ne se dessine pas, pourtant j'ai déjà utilisé cette commande).
Je pense qu'une partie de mes problèmes a pour origine mon ordinateur (compilation très longue, bugs,...)
Merci.

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Lun 3 Nov - 15:47

Salut Fabrice,

Avant de me plonger dans l'exemple. Es-tu sûr et certain des centres des trois sphères qui sont sur le plan? Car celles-ci ne sont pas tangentes, mais c'est peut-être voulu?

Le fait que la sphère du dessus soit tangente ou non n'a rien à voir avec theta et phi, c'est que le centre n'est pas correctement placé. D'où ma question précédente.

PS: Là il commence à y avoir des facettes! Pour allèger, il vaut mieux activer l'option backculling:=1, qui a pour effet d'éliminer les facettes non visibles:

Code:

 Build3D(bdFacet(S1, [color:=red, backculling:=1, gouraud:=1]),
          bdFacet(S2, [color:=steelblue, backculling:=1,gouraud:=1]),
          bdFacet(S3, [color:=yellow,backculling:=1, gouraud:=1]),
          bdFacet(S4, [color:=green, backculling:=1, gouraud:=1]),
          bdPlan(P,[color:=ivory,opacity:=0.75])),

Il y a un problème avec l'option scale (c'est := et non = et sa valeur par défaut est déjà 1), et avec la valeur 0,75 (c'est 0.75).
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Lun 3 Nov - 16:36

Re,

Si Build3D est trop long sur ta machine, il y a une autre solution (sur cet exemple j'ai mis les 4 sphères tangentes):

Code:

[view3D(-5,5,-5,5,-6,6), view(-6,6,-5,6), Marges(0,0,0,0), size(12,1),
  $a:=4*sqrt(3)/3,
  C1:=[a,0], C2:=[a*exp(i*2*pi/3),0], C3:=[a*exp(-2*i*pi/3),0],
  C4:=(C1+C2+C3)/3,
  S1:=Sphere(C1,2,25,25),
  S2:=Sphere(C2,2,25,25),
  S3:=Sphere(C3,2,25,25),
  S4:=Sphere(pxy(C4)+[0,4*sqrt(2/3)],2,25,25),
  P:=[M(0,0,-2),vecK],
  DrawMixFacet(
              S1, [color:=red, backculling:=1, gouraud:=1],
              S2, [color:=steelblue, backculling:=1,gouraud:=1],
              S3, [color:=yellow, backculling:=1,gouraud:=1],
              S4, [color:=green, backculling:=1,gouraud:=1],
              getplan(P),[color:=ivory]
              )
]

Ce qui me donne: Empilement de boules Fabsph10

La différence est que DrawMixFacet() classe les facettes suivant leur éloignement mais sans les découper en cas d'ambiguité ce qui fait que cela ne marche pas toujours, (alors que Build3D découpe les facettes).
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  F.Couvreur Mar 4 Nov - 3:26

Bonsoir Patrick,

P.Fradin a écrit:Salut Fabrice,
Avant de me plonger dans l'exemple. Es-tu sûr et certain des centres des trois sphères qui sont sur le plan? Car celles-ci ne sont pas tangentes, mais c'est peut-être voulu?

Le fait que la sphère du dessus soit tangente ou non n'a rien à voir avec theta et phi, c'est que le centre n'est pas correctement placé. D'où ma question précédente.
Ce n'est pas voulu, j'ai tout simplement fait un copier-coller d'un autre code sans réfléchir ! Embarassed
Voici ce qui devait être le bon code :
Code:
[view3D(-8,8,-8,8,-6,6),Marges(0,0,0,0),
  S1:=Sphere([0-2*i,0],2,25,25),
  S2:=shift3d(S1,4*vecJ),
  S3:=shift3d(S1,2*sqrt(2)*(vecJ+vecI)),
  S4:=Sphere([(2*sqrt(2))/3+0*i,2*sqrt(3)],2,25,25),
  P:=[M(0,0,-2),vecK],
  Build3D(bdFacet(S1, [color:=red, gouraud:=1]),
          bdFacet(S2, [color:=steelblue, gouraud:=1]),
          bdFacet(S3, [color:=yellow, gouraud:=1]),
          bdFacet(S4, [color:=green, gouraud:=1]),
          bdPlan(P,[color:=ivory,opacity=0.75])),
  Display3D()] 
Je n'enseigne pas en Term S, et je n'ai plus le réflexe d'utiliser les nombres complexes, je régresse ! Very Happy

Il y a un problème avec l'option scale (c'est := et non = et sa valeur par défaut est déjà 1), et avec la valeur 0,75 (c'est 0.75).
Erreur de ma part (confusion fréquente entre le point et la virgule !).
J'ai testé ton code, et ce que je ne comprends pas, c'est que les "coins" du parallélogramme sont coupés.
Si je rajoute view(-6,6,-5,6), size(12,1) à mon code ci-dessus, je n'ai pas le plan P sous la forme d'un parallélogramme comme le montre l'image que tu as jointes.
De plus, je ne parviens toujours pas à dessiner une flèche.
Merci.
PS: J'ai eu une journée très mouvementée, ceci explique peut-être cela !

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 12:41

Bonjour Fabrice,

Il me semble que tes sphères ne sont encore pas tangentes! Alors je récidive avec mon code mais sans complexes cette fois-ci Laughing :

Code:

[view3D(-5,5,-5,5,-6,6), view(-8,8,-6,6), Marges(0,0,0,0), size(12,1),
 $a:=4*sqrt(3)/3,
 C1:=M(a,0,0), C2:=M(-a/2, a*sqrt(3)/2, 0), C3:=M(-a/2, -a*sqrt(3)/2, 0),
 C4':=(C1+C2+C3)/3, {centre de gravité}
 C4:= pxy(C4')+M(0,0,4*sqrt(2/3)),
 S1:=Sphere(C1,2,25,25), S2:=Sphere(C2,2,25,25),
 S3:=Sphere(C3,2,25,25), S4:=Sphere(C4,2,25,25),
 P:=[M(0,0,-2),vecK], h:=Zde(C4)+4,
 A:=M(4,-4,-2), B:=A+M(0,0,h),
 Build3D(bdPlan(P,[color:=ivory,scale=0.75]),
        bdFacet(S1, [color:=red, backculling:=1, gouraud:=1]),
        bdFacet(S2, [color:=steelblue, backculling:=1,gouraud:=1]),
        bdFacet(S3, [color:=yellow, backculling:=1,gouraud:=1]),
        bdFacet(S4, [color:=green, backculling:=1,gouraud:=1]),
        bdLine(Bord(getplan(P)),[width:=12]),
        ),
 Display3D(),
 LineStyle:=dashed, Ligne3D([B,C4+M(0,0,2)],0),LineStyle:=solid,
 Width:=8, Arrows:=2,  Ligne3D([A,B],0),
 LabelDot(Proj3D((A+B)/2), "h","O")
 ]

Si les coins étaient coupés c'était parce que la fenêtre 2D n'était pas assez large (je l'ai élargie). Par contre attention à l'export, si tu veux des facettes lissées je te conseille eps ->jpg (bouton snapshot).

Empilement de boules Fabsph11
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  F.Couvreur Mar 4 Nov - 15:14

Salut Patrick,
Je ne sais pas si je vais encore intervenir sur ce forum tant j'ai honte de moi !
Embarassed
En préparant cet exercice, j'ai considéré que les centres des trois sphères du bas se trouvaient sur les sommets d'un triangle équilatéral de longueur de côté 4. Je voulais utiliser les translations car je vais aborder le cours prochainement. Malheureusement, j'ai cafouillé avec les racines carrées, et le vecteur de translation qui permettait de construire la sphère C3 à partir de C1 était 2*(VecJ+sqrt(3)*VecI), enfin je crois !
En tout cas, le rendu est superbe !
Merci beaucoup.

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 15:23

F.Couvreur a écrit:Salut Patrick,
Je ne sais pas si je vais encore intervenir sur ce forum tant j'ai honte de moi !
Embarassed

Ne t'inquiète pas pour ça, j'ai déjà fait bien pire...
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  F.Couvreur Mar 4 Nov - 17:09

Salut,
Ne t'inquiète pas pour ça, j'ai déjà fait bien pire...
Merci pour le soutien moral, mais....
Il y a encore un petit problème : j'ai récupéré ton fichier pour le tester, et j'ai le même rendu sauf pour le contour en noir du plan P qui n'apparaît pas.
Merci.

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 18:08

Tu as la version 1.94-beta-7.2?
Je crois que celles d'avant n'avaient pas la commande Bord.
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  F.Couvreur Mar 4 Nov - 18:36

Re,
Je viens de mettre à jour car je disposais de la version 1.94-beta-7.1, et c'est ok.
Je me suis posé la question suivante : ne faut-il pas dessiner le tétraèdre régulier avec à l'intérieur l'empilement pour aider les élèves?
Qu'en penses-tu ?
Le rendu sera-t-il toujours aussi superbe ?

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 19:10

F.Couvreur a écrit:Re,
Je viens de mettre à jour car je disposais de la version 1.94-beta-7.1, et c'est ok.

A la bone heure!


Je me suis posé la question suivante : ne faut-il pas dessiner le tétraèdre régulier avec à l'intérieur l'empilement pour aider les élèves?
Qu'en penses-tu ?
Le rendu sera-t-il toujours aussi superbe ?

C'est vrai que cela aiderait à comprendre comment placer les centres des sphères et faire les calculs. J'ai donc modifié un peu le code pour rajouter le tétraèdre en pointillés:

Code:

[view3D(-5,5,-5,5,-6,6), view(-8,8,-6,6), Marges(0,0,0,0), size(12,1),
 $a:=4*sqrt(3)/3,
 C1:=M(a,0,0), C2:=M(-a/2, a*sqrt(3)/2, 0), C3:=M(-a/2, -a*sqrt(3)/2, 0),
 C4':=(C1+C2+C3)/3, {centre de gravité}
 C4:= pxy(C4')+M(0,0,4*sqrt(2/3)),
 S1:=Sphere(C1,2,25,25), S2:=Sphere(C2,2,25,25),
 S3:=Sphere(C3,2,25,25), S4:=Sphere(C4,2,25,25),
 P:=[M(0,0,-2),vecK], h:=Zde(C4)+4,
 A:=M(4,-4,-2), B:=A+M(0,0,h),
 Build3D(bdPlan(P,[color:=ivory,scale=0.75]),
        bdFacet(S1, [color:=firebrick, backculling:=1, gouraud:=1]),
        bdFacet(S2, [color:=steelblue, backculling:=1,gouraud:=1]),
        bdFacet(S3, [color:=orange, backculling:=1,gouraud:=1]),
        bdFacet(S4, [color:=darkseagreen, backculling:=1,gouraud:=1]),
        bdLine(Bord(getplan(P)),[width:=12]),
        ),
 Display3D(),
 LineStyle:=dashed, Ligne3D([B,C4+M(0,0,2)],0),
 LineStyle:=dotted, Width:=6, Ligne3D(Tetra(C1,C2-C1,C3-C1,C4-C1),1),
 LineStyle:=solid, Width:=4,
 Width:=8, Arrows:=2,  Ligne3D([A,B],0),
 LabelDot(Proj3D((A+B)/2), "h","O")
 ]

Empilement de boules Fabsph12

Quant au rendu, cela dépendra surtout de ton imprimante!
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  F.Couvreur Mar 4 Nov - 19:20

Re,
L'empilement ne doit-il pas se trouver à l'intérieur du tétraèdre ?
Autrement dit, les sphères ne doivent-elles pas être tangentes aux faces du tétraèdre ?

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 20:48

Ca dépend de quel tétraèdre tu parles! Les 4 centres forment aussi un tétraèdre régulier, d'ailleurs les deux sont homothétiques par rapport au centre de gravité des 4 centres.

J'ai donc modifié le code ainsi:

Code:

[view3D(-9,9,-8,8,-6,6), view(-12,12,-9,10), Marges(0,0,0,0), size(12,1),
 $a:=4*sqrt(3)/3,
 C1:=M(a,0,0), C2:=M(-a/2, a*sqrt(3)/2, 0), C3:=M(-a/2, -a*sqrt(3)/2, 0),
 C4':=(C1+C2+C3)/3, {centre de gravité}
 C4:= pxy(C4')+M(0,0,4*sqrt(2/3)),
 S1:=Sphere(C1,2,25,25), S2:=Sphere(C2,2,25,25),
 S3:=Sphere(C3,2,25,25), S4:=Sphere(C4,2,25,25),
 P:=[M(0,0,-2),vecK], h:=Zde(C4)+4,
 A:=M(4,-4,-2), B:=A+M(0,0,h),
 G:=(C1+C2+C3+C4)/4, G':=pxy(G), k:=1+2/Norm(G'-G),
 T:=hom3d( Tetra(C1,C2-C1,C3-C1,C4-C1), G, k),
 Build3D(bdPlan(P,[color:=ivory]),
        bdFacet(T,[color:=Rgb(0.8,0.6,1),opacity:=0.5]),
        bdFacet(S1, [color:=firebrick, backculling:=1, gouraud:=0]),
        bdFacet(S2, [color:=steelblue, backculling:=1,gouraud:=0]),
        bdFacet(S3, [color:=orange, backculling:=1,gouraud:=0]),
        bdFacet(S4, [color:=darkseagreen, backculling:=1,gouraud:=0]),
        bdLine(Bord(getplan(P)),[width:=12]),
        bdLine(Aretes(T),[width:=12]),
        ),
 Display3D(),
 LineStyle:=dashed, Ligne3D([B,C4+M(0,0,2)],0),LineStyle:=solid,
 Width:=8, Arrows:=2,  Ligne3D([A,B],0),
 LabelDot(Proj3D((A+B)/2), "h","O")
 ]

Je n'ai pas lissé les facettes ici car à cause de la transparence il faut passer par pdf pour avoir le jpg correct, mais je ne sais pas pourquoi, convert met un temps fou à convertir le pdf en jpg, comme j'en ai marre d'attendre, je poste une capture de l'aperçu:

Empilement de boules Fabsph13
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 21:17

Ca y est! convert a fini, il a bien fallu un quart d'heure! Voici l'image avec les facettes lissées:

Empilement de boules 081104072027606067
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  Eric Kouris Mar 4 Nov - 21:20

Ça a de la gueule Exclamation Exclamation Exclamation

Eric Kouris

Nombre de messages : 150
Age : 56
Date d'inscription : 26/03/2008

http://pagesperso-orange.fr/styren/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 21:27

Eric Kouris a écrit:Ça a de la gueule Exclamation Exclamation Exclamation

Salut Eric,

Et ça a plus de gueule avec l'export geom pour geomview (si tu es sous linux, mais c'est possible aussi sous windows), car dans ce logiciel de visualisation 3D la figure est manipulable à la souris dans l'espace et c'est très fluide.
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  F.Couvreur Mar 4 Nov - 21:43

Bonsoir,
Ça a de la gueule
+1
TeXgraph, alias Pierre Fradin, c'est formidable !
Merci beaucoup.

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Mar 4 Nov - 21:47

F.Couvreur a écrit:
TeXgraph, alias Pierre Fradin, c'est formidable !
Merci beaucoup.

Ah non! Moi c'est Patrick affraid
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  F.Couvreur Mar 4 Nov - 22:03

Re,
Quand je te disais que rien ne va en ce moment ! No
Mille excuses Patrick !

F.Couvreur

Nombre de messages : 137
Age : 61
Date d'inscription : 10/02/2008

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  Joffrey Jeu 6 Nov - 20:24

Bonjour à tous,

Très jaloux des si belles figures que vous obtenez, je me suis dit que j'allais m'y mettre!! What a Face

Mais j'ai un problème; j'ai utilisé une partie du code, à savoir :
Code:
[
 view3D(-9,9,-8,8,-6,6), view(-12,12,-9,10), Marges(0,0,0,0), size(12,1),
 $a:=4*sqrt(3)/3,
 C1:=M(a,0,0),
 S1:=Sphere(C1,2,25,25),
 Build3D(bdFacet(S1, [color:=steelblue, backculling:=1,gouraud:=0]),
        ),
 Display3D(),
dans une fenêtre utilisateur.
Lorsque je demande un export en jpg ou png rien ne se passe; si ce n'est dans le dossier C:\tmp où un fichier snapshot.pdf apparaît.

Il y a surement quelque chose que je ne fait pas correctement.

Joffrey

Joffrey

Nombre de messages : 179
Age : 42
Localisation : Vichy(03) / Clermont-Ferrand(63)
Date d'inscription : 13/06/2008

http://mathex.servhome.org

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Jeu 6 Nov - 20:30

Salut Joffrey,

Tu as le snapshot.eps, c'est bon signe! Qu'est-ce qui manque? Et bien l'utilitaire convert d'ImageMagick peut-être? Tu as installé ImageMagick?

Si oui, c'est peut-être que tu n'attends pas assez longtemps, la conversion pdf -> jpg par convert peut-être trèèèèèèèèèèèèèèèès longue (c'est bien plus rapide de eps vers jpg, mais en eps on n'a pas la transparence...)
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  Joffrey Jeu 27 Nov - 0:22

Bonsoir,

Je reprends le fil que j'avais laissé en attente.

P.Fradin a écrit :
Tu as installé ImageMagick??

Oui, ImageMagick 6.4.5 Q16 pour être précis. J'ai toujours mon snapshot.pdf mas pas de pas de jpg.

Et bien l'utilitaire convert d'ImageMagick peut-être?

Est-ce un utilitaire à part à prendre via le site officiel ou une fonctionnalité d' ImageMagick?
J'avoue ne pas être très doué dans ce genre de manipulation.

Merci

Joffrey

Joffrey

Nombre de messages : 179
Age : 42
Localisation : Vichy(03) / Clermont-Ferrand(63)
Date d'inscription : 13/06/2008

http://mathex.servhome.org

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Jeu 27 Nov - 0:30

Bonsoir Joffrey,

L'utilitaire fait partie d'ImageMagick (qui est un ensemble d'utilitaires). Ouvre une fenêtre Dos et tape la commande convert et dis-moi la réponse.
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  Joffrey Jeu 27 Nov - 0:35

bcp de lignes dont la premiere en reference a la version d'imageMagick que j'utilise

Joffrey

Joffrey

Nombre de messages : 179
Age : 42
Localisation : Vichy(03) / Clermont-Ferrand(63)
Date d'inscription : 13/06/2008

http://mathex.servhome.org

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  P.Fradin Jeu 27 Nov - 0:44

Bien,

Place toi dans le dossier où tu as le fichier snapshot.pdf et tape la commande:

convert -density 300 -scale 32% -depth 8 -quality 100 snapshot.pdf snapshot.jpg

et dis moi ce qui se passe.
P.Fradin
P.Fradin
Admin

Nombre de messages : 1133
Age : 62
Date d'inscription : 19/01/2008

http://texgraph.tuxfamily.org/

Revenir en haut Aller en bas

Empilement de boules Empty Re: Empilement de boules

Message  Contenu sponsorisé


Contenu sponsorisé


Revenir en haut Aller en bas

Page 1 sur 2 1, 2  Suivant

Revenir en haut


 
Permission de ce forum:
Vous ne pouvez pas répondre aux sujets dans ce forum
Ne ratez plus aucun deal !
Abonnez-vous pour recevoir par notification une sélection des meilleurs deals chaque jour.
IgnorerAutoriser