Points d'une courbe paramétrée

Voici un dessin qu'on m'a plusieurs fois demandé en privé, il s'agit des 4 types de points d'une courbe paramétrée. On crée d'abord la macro legende avec la commande:

Code:


if %1=1 then "Point ordinaire"
elif %1=2 then "Point d'inflexion"
elif %1=3 then "Rebroussement 1ère espèce"
else "Rebroussement 2ème espèce"
fi


puis un élément graphique Utilisateur avec la commande:

Code:


[Width:=6,
{points de contrôle bezier1}
A:=(1+i)*0.75, B:=0.75, C:=0,
{points de controle bezier2}
A':=[-1.25+i*0.5, -0.75-i*0.5, 1.25-0.5*i, 0.5+i], B':=[-0.75,-0.75,0.75,0.75],
{vecteurs de tanslation}
u:=[-3+2.5*i, 3+2.5*i,-3-2.5*i,3-2.5*i],

for k from 1 to 4 do
    SaveAttr(),
    SetMatrix([u[k],1.5,i*1.5+1]),{le dessin se fait dans [-1,1]x[-1,1]}
    {axes}
    Ligne([-1,1,jump,-i,i],0),
    {courbes bezier1 et bezier2}
    Width:=8, Color:=blue, Bezier(C, (C+5*B)/6, (B+2*A)/3, A),
    Bezier(C, (C+5*B'[k])/6, (B'[k]+2*A'[k])/3, A'[k]),
    {vecteurs}
    Color:=red, Arrows:=1, Ligne([0,0.75,jump,0,0.75*i],0), Arrows:=0,
    {noms vecteurs}
    Color:=black, LabelDot(1,"$f^{(p)}(t_0)$","E",0,0.35),
    LabelDot(0.75*i,"$f^{(q)}(t_0)$","O",0,0.35),
    {légende}
    LabelDot(-i+1, \legende(k), "S",0),
    RestoreAttr()
od]


l'idée est de faire un seul dessin dans [-1,1]x[-1,1], mais dans une boucle pour k allant de 1 à 4, en utilisant la matrice de transformation pour "pencher" l'axe Oy et translater le tout.

Ce qui donne:

Très joli