Triangle sphérique

Bonjour,
abonné à la liste de diffusion de syracuse, je viens de m'inscrire sur ce forum. Je suis enseignant et j'ai en charge des classes de BTS géomètre-topographe, aussi ce fabuleux logiciel (TeXgraph) m'est utile quasiment tous les jours et j'en profite pour remercier Patrick Fradin pour son formidable travail [ici et sur la liste de syracuse]
Je dois représenter des triangles sphériques et pour cela, je crée une sphère puis les grands cercles correspondants, ensuite je supprime un certain nombre de points dans le fichier .tex produit. Ma question est simple : est-il possible sur une sphère de ne faire apparaitre qu'une portion de grand cercle (en entrant par exemple l'angle de départ et l'angle d'arrivée) ? Je n'ai rien trouvé de prévu à cet effet dans le logiciel...
Si ma question a déjà été posée, toutes mes sincères excuses... Merci d'avance pour une réponse éventuelle et merci encore pour TeXgraph.

François.

Bonjour françois,

Oui c'est possible. Je dois partir en cours, je répondrai plus longuement ce soir.

Merci Patrick pour cette réponse si rapide...
J'attends ta (on peut se tutoyer ?) réponse... Bon cours et merci encore.

Me revoilà,

Je te propose une macro triangleS qui s'utiliserait ainsi: triangleS( centre, rayon, A, B, C), et définie par la commande:

Code:


{ triangleS(centre,rayon, R,A,B,C)}
[$O:=%1, $R:=%2, $A:=%3, $B:=%4,$C:=%5,
 Ligne([ Get(Arc3D(B,O,A,R,1)), Get(Arc3D(A,O,C,R,1)), Get(Arc3D(C,O,B,R,1))],0)
]


Les points de l'espace n'ont pas besoin d'être exactement sur la sphère de centre de O et de rayon R. Un petit exemple pour tester dans un élément graphique Utilisateur:

Code:


[Width:=8, O:=[0,0],
 Dsphere(O, 3,0),
 A:=M(1,1,5), B:=M(1,0,0), C:=M(0,1,0),
 FillStyle:=full, FillColor:= blue, triangleS(O,3,A,B,C),
 A':=3*normalize(A), B':=3*normalize(B), C':=3*normalize(C),
 LabelDot(Proj3D(A'),"$A$","N",1),
 LabelDot(Proj3D(B'),"$B$","SO",1),
 LabelDot(Proj3D(C'),"$C$","SE",1) ] 


Bonsoir Patrick,
n'ayant pas pu répondre avant car étant en week-end, je m'empresse d'allumer mon pc pour te remercier vivement de ta réponse... La vais tester cela très vite... Merci encore et bonne fin de week-end.

François.

Bonjour
j'en profite pour demander un petit service,
ça fait 1h30 que j'essaie de faire une figure sans succès :
il faudrait que ce soit ceci : http://melusine.eu.org/lab/bjps/dessins3d/geom_spherique/triangle_spherique_05.jps

bon après les couleurs et tout je pense que j'arriverai à changer si ça me convient pas, mais ce qu'il faut ajouter surtout, c'est que je voudrais qu'il y ait marqué T a l'intérieur du triangle principal, et ensuite -T dans le triangle opposé, A B et C et -A -B et -C avec les autres triangles adjacents à T.
j'espère avoir été clair dans mes explications.

Merci de me donner un petit coup de main

Bonjour homer,

En utililsant la macro triangleS proposée dans le premier post de ce fil, je te propose ce code:

Code:


[Width:=8, O:=[0,0],
 A:=3*normalize(M(1,1,5)), B:=3*normalize(M(1,1,0.25)), C:=3*normalize(M(0,1,0.5)),
 T:=bary3d([A,1,B,1,C,2]),
 FillStyle:=full, FillColor:= lightblue, triangleS(O,3,-A,-B,-C),
 Width:=2, FillStyle:=none, Color:=gray, Ligne3D( Sphere(O,3,25,25),1),
 Color:=black, Width:=8, FillStyle:=full, FillColor:= blue, triangleS(O,3,A,B,C),

 FillStyle:=none, LineStyle:= dashed,
 Cercle3D( O, 3, Prodvec(A,B)),
 Cercle3D( O, 3, Prodvec(A,C)),
 Cercle3D( O, 3, Prodvec(C,B)),

 LabelDot(Proj3D(A),"$A$","NE",1), LabelDot(Proj3D(B),"$B$","O",1),
 LabelDot(Proj3D(C),"$C$","E",1), Label(Proj3D(T),"$T$"),
 LabelDot(Proj3D(-A),"$-A$","N",1), LabelDot(Proj3D(-B),"$-B$","N",1),
 LabelDot(Proj3D(-C),"$-C$","O",1), Label(Proj3D(-T),"$-T$")
 ]


ce qui me donne ceci:


Pour les triangles sphériques adjacents, c'est un peu plus compliqué, car la macro actuelle est très simpliste, elle ne traite correctement que les triangles qui sont entièrement cachés ou entièrement visibles. Que veux-tu faire précisément pour les adjacents?

Pour gérer les triangles sphériques dans toutes les positions, je propose une nouvelle macro triangleSb qui renvoie le triangle sphérique sous forme de facettes, en affichant les différents éléments avec la commande Build3D(), la scène est automatiquement gérée (parties cachées).

J'ai ajouté une macro oppFacet() qui renvoie la liste des facettes après avoir multiplié chaque sommet par -1 et réorienté le tout. Le code suivant:

Code:


[O:=[0,0],
 A:=3*normalize(M(1,1,5)), B:=3*normalize(M(1,1,0.25)), C:=3*normalize(M(0,1,0.5)),
 T:=bary3d([A,1,B,1,C,2]),
 Tabc:=triangleSb(O,3,A,B,C), Tabc':=oppFacet(Tabc),
 Tab:=triangleSb(O,3,B,A,-C), Tab':= oppFacet(Tab),
 Tac:=triangleSb(O,3,A,C,-B), Tac':= oppFacet(Tac),
 Tbc:=triangleSb(O,3,C,B,-A), Tbc':= oppFacet(Tbc),
Build3D(
        bdFacet(Tabc, [color:=blue, contrast:=0.25]),
        bdFacet(Tabc', [color:=blue, contrast:=0.25]),
        {triangles adjacents à (A,B,C)}
        bdFacet(Tab, [color:=lightseagreen, opacity:=0.5, contrast:=0.25]),
        bdFacet(Tbc, [color:=coral, opacity:=0.5, contrast:=0.25]),
        bdFacet(Tac, [color:=gold, opacity:=0.5, contrast:=0.25]),
        {triangles adjacents à (-A,-B,-C)}
        bdFacet(Tbc', [color:=firebrick, opacity:=0.5, contrast:=0.25]),
        bdFacet(Tac', [color:=magenta, opacity:=0.5, contrast:=0.25]),
        bdFacet(Tab', [color:=cyan, opacity:=0.5, contrast:=0.25]),
        bdCercle(O,3.01,Prodvec(A,B)),
        bdCercle(O,3.01,Prodvec(A,C)),
        bdCercle(O,3.01,Prodvec(C,B)),
      ),
Display3D(),
 Width:=4, FillStyle:=none, LineStyle:= dashed,
 Cercle3D( O, 3, Prodvec(A,B)), Cercle3D( O, 3, Prodvec(A,C)), Cercle3D( O, 3, Prodvec(C,B)),
 LabelDot(Proj3D(A),"$A$","NE",1), LabelDot(Proj3D(B),"$B$","O",1),
 LabelDot(Proj3D(C),"$C$","E",1), Label(Proj3D(T),"$T$"),
 LabelDot(Proj3D(-A),"$-A$","N",1), LabelDot(Proj3D(-B),"$-B$","N",1),
 LabelDot(Proj3D(-C),"$-C$","O",1), Label(Proj3D(-T),"$-T$"),
]


donne alors:


Le fichier source avec les macros triangleS.teg.

Bonsoir,
Merci Beaucoup Patrick, une fois de plus

La première macro me va parfaitement, dans l'idéal il aurait fallau mettre un label A à un des 3 triangles adjacent et T, et -A pour son opposé comme pour -T, et pareil pour B et C ... mais au final cela deviendrait ptete illisible...
là avec T et -T, on peut clairement expliquer que l'on fait pareil pour les triangles adjacents, et voilà le travail.

Merci beaucoup pour le coup de pouce, j'ai bien galéré

Bonne soirée et encore merci


Edit : bon j'ai modifié 2/3 trucs, mais rien de bien méchant, et 2 constats : l'aperçu ne marche pas, mais après export et compilation de apercu.tex, j'obtiens bien ce que je veux, mais sans couleur

homer3018 a écrit:Bonsoir,
Merci Beaucoup Patrick, une fois de plus

Bonsoir homer, ce fut un plaisir

La première macro me va parfaitement, dans l'idéal il aurait fallau mettre un label A à un des 3 triangles adjacent et T, et -A pour son opposé comme pour -T, et pareil pour B et C ... mais au final cela deviendrait ptete illisible...

Avec la figure en fil de fer cela ne serait peut-être pas très lisible en effet. Ce serait plus clair avec la deuxième figure car tous les triangles sont peints dans celle-ci.

là avec T et -T, on peut clairement expliquer que l'on fait pareil pour les triangles adjacents, et voilà le travail.

Oui, une figure aide à stimuler l'imagination, mais ne doit pas remplacer l'imagination .

Bonne soirée et encore merci

Pas de quoi.
A bientôt.

t'as répondu plus vite que mon edit lol

Edit : bon j'ai modifié 2/3 trucs, mais rien de bien méchant, et 2 constats : l'aperçu ne marche pas, mais après export et compilation de apercu.tex, j'obtiens bien ce que je veux, mais sans couleur

homer3018 a écrit:t'as répondu plus vite que mon edit lol

Edit : bon j'ai modifié 2/3 trucs, mais rien de bien méchant, et 2 constats : l'aperçu ne marche pas, mais après export et compilation de apercu.tex, j'obtiens bien ce que je veux, mais sans couleur

Poste ton code que je l'essaie.

[Width:=8, O:=[0,0],
A:=3*normalize(M(1,1,5)), B:=3*normalize(M(1,1,0.25)), C:=3*normalize(M(0,1,0.5)),
T:=bary3d([A,1,B,1,C,2]),
FillStyle:=full, FillColor:=lightblue, triangleS(O,3,-A,-B,-C),
Width:=1, FillStyle:=none, Color:=lightgray, Ligne3D( Sphere(O,3,50,50),1),
Color:=black, Width:=8, FillStyle:=full, FillColor:=blue, triangleS(O,3,A,B,C),

FillStyle:=none, LineStyle:= dotted,
Cercle3D( O, 3, Prodvec(A,B)),
Cercle3D( O, 3, Prodvec(A,C)),
Cercle3D( O, 3, Prodvec(C,B)),

LabelDot(Proj3D(A),"$A$","NE",1), LabelDot(Proj3D(B),"$B$","O",1),
LabelDot(Proj3D(C),"$C$","E",1), Label(Proj3D(T),"$T$"),
LabelDot(Proj3D(-A),"$-A$","N",1), LabelDot(Proj3D(-B),"$-B$","N",1),
LabelDot(Proj3D(-C),"$-C$","O",1), Label(Proj3D(-T),"$-T$")
]

Chez moi ton code fonctionne parfaitement, l'aperçu me donne ceci:



Export tex: pas de remplissage, c'est normal, c'est export est trop basique. L'export pgf ou pstricks est préférable.

Pas d'aperçu: tu as un problème d'installation (pgf à jour? des espaces dans le chemin d'accès à TeXgraph?)

Arf
bon alors maintenant je suis sur mon portable, où j'ai la version 93, et là j'ai uniquement la sphère (je viens de cc le code du dessus) ... et aperçu ne fais RIEN encore mieux :/
hier soir ça ouvrait adobe mais donnait une erreur, là keudal

et j'ai même pas mes triangles.... :-(

et le chemin d'accès : C:\TeXgraph1.93\TeXgraph\texgraph.exe

edit : c'est bon, pour vista, j'ai juste dû changer le chemin d'accès à adobe dans le .bat
j'ai bien mon aperçu mais uniquement la sphère ce qui est un peu dérangeant étant donné que j'ai cc le code qui me donnait la presque bonne figure hier, et la bonne chez toi alors bon ...
mais ça avance

Bonjour,

Je te recommande plutôt la version 1.94 dernière mouture, mais bon, chez moi j'ai également la bonne figure avec la version 1.93. Si tu n'as pas les triangles peut-être as-tu tout simplement oublié la macro triangleS?

PS: le fonctionnement de l'aperçu est entièrement décrit dans l'aide, je ne peux rien faire de plus. La version 1.94 a un fichier de configuration (menu Paramètres) où on peut indiquer le lecteur pdf.

ok je vais changer la version mais bon...
sinon , non je n'ai pas oublié la macro, je l'ai bien ajouter dans la case macro, mais rien n'y fait

La macro triangleS étant trop basique à mon goût, je l'ai améliorée pour tenir compte des cas où une partie seulement du triangle est visible/invisible. Ce qui permet de dessiner des triangles adjacents dans le cas de la figure fil de fer:



Le fichier source est là: triangleS.teg.

Super,
c'est bon tout est ok de mon côté, avec la version 94, tout marche (il manquait l'apercu.bat, mais un petit copier coller a réglé le problème)
tout marche enfin correctement
Merci pour l'autre teg il me sera aussi utile je pense

Merci merci merci (mais je reviendrai avec d'autres défis !)

edit : http://upload.wikimedia.org/wikipedia/commons/thumb/1/14/Triangle_sph%C3%A9rique.svg/320px-Triangle_sph%C3%A9rique.svg.png

et un truc comme ça, mais juste en 2d, c'est possible ? je galère avec mes arcs de cercles...ou alors j'ai pas tout compris a texgraph

Bonjour homer,

Voilà un autre problème inréressant lorsqu'on veut que la gestion des pointillés soit automatique! Je te propose le fichier suivant: triangleS2.teg,

le code de l'élément graphique est:

Code:


[Width:=8, O:=[0,0],
 A:=3*normalize(M(1,1,5)), B:=3*normalize(M(1,1,0.25)), C:=3*normalize(M(0,1,0.5)),
 Cercle(0,3),
 FillStyle:=full, FillColor:= blue, triangleS(O,3,A,B,C),
 FillStyle:=none,
 grandCercle( O, 3, A,B,"c","O"),
 grandCercle( O, 3, A,C,"b","E"),
 grandCercle( O, 3, C,B,"a","S"),
 angleS(O,3,B,A,C,0.5,1,"$\alpha$"),
 angleS(O,3,C,B,A,0.5,1, "$\beta$"),
 angleS(O,3,A,C,B,0.5,1,"$\gamma$"),
 LabelDot(Proj3D(A),"$A$","N",1),
 LabelDot(Proj3D(B),"$B$","SO",1),
 LabelDot(Proj3D(C),"$C$","E",1),
]


ce qui donne:



Je repondrai plus longuement ce soir s'il faut des éclaircissements.

Tout d'abord, encore merci pour ces merveilleux bout de code

du coup j'ai modifié tous les dessins d'avant avec ta macro GrandCercle pour avoir des pointillé et tout, et aussi triangleS pour avoir les triangles de "derriere" en pointillé, enfin bref je me suis débrouillé, et tout me convient parfaitement...

J'ai encore pas mal de dessins à faire, et même les plus simples me donnent du fil à retordre...
c'est sûr je pratique pas assez texgraph, mais quand même, il me faudrait une formation

Voilà une liste de dessins d'un livre, que j'ai besoin d'intégrer à mon mémoire :








pour celle- ci, il me faudrait plutôt deux fichiers,ensuite encore :









voilà....
j'espère que ça ne prendra pas trop de temps à réaliser, je sais que je demandes beaucoup...

Il ne s'agit plus de triangles sphériques, mais d'hyperboliques au débuts, puis des pavages euclidiens, sphériques et hyperboliques.

Un grand MERCI d'avance...
j'aimerai pouvoir renvoyer l'ascenseur mais je ne sais pas comment faire.

Bonjour homer,

J'éditerai ce message au fur et à mesure des figures.

Code: [view(-4,4,-0.5,4.5), Marges(0,0,0,0), size(10), a:=3*exp(i*pi/8), b:=4*exp(i*pi/3), c:=-bar(b), d:=-bar(a), Arrows:=1, Width:=12, Ligne([0,a,jump,0,b,jump,0,c,jump,0,d],0), Arrows:=0, LabelDot(a, "$z\times z$", "NE"), LabelDot(b, "$h'(0)", "N"), LabelDot(c, "$-g'(b)$", "N"), LabelDot(d, "$x\times y$", "NO"), {LabelArc( B, A, C, R, sens, "texte", [labelsep:=0.25]) } LabelArc( a,0,b,2,1, "$\frac{\pi}2-\alpha$", [LabelStyle:=left]), LabelArc( b,0,c,1.5,1, "$\alpha$"), LabelArc( c,0,d,2,1, "$\frac{\pi}2-\alpha$", [LabelStyle:=right]) ]
Code: [view(-3,3,-1.5,2.5), Marges(0,0,0), size(10),  z:=2*exp(-i*pi/6), y:=exp(i*2*pi/3)*z, x:=exp(i*4*pi/3)*z,  O1:=-5*i, O2:=exp(i*2*pi/3)*O1,O3:=exp(i*4*pi/3)*O1, R:=abs(O1-x),  Width:=12,  Path([x,O1,z,R,-1,arc,O2,y,R,-1,arc,O3,x,R,-1,arc],0),  LabelDot( z, "$z$", "SE"),  LabelDot( y, "$y$", "N"),  LabelDot( x, "$x$", "SO"),  Label( (y+z)/2, "$a$", (x+z)/2, "$b$",(x+y)/2, "$c$"),  Label( y/2, "$\beta$", exp(i*2*pi/3)*y/2, "$\alpha$", exp(i*4*pi/3)*y/2, "$\gamma$") ]
Code: [view(-3.5,3.5,-3.5,3.5), Marges(0,0,0,0), size(10),  r:=3, alpha:= pi/4, Width:=12,  Cercle(0,r), Ligne([0,3*exp(i*alpha), 3*exp(-i*alpha)],1),  LabelDot( 0, "$e_1$", "O"), LabelDot( 0, "$\alpha$", "E"),  LabelDot( 3*cos(alpha), "$L$", "O") ]
Code: [view(-3.5,3.5,-3.5,3.5), Marges(0,0,0,0), size(10),  r:=3, x:=r*exp(-i*pi/6), y:=exp(i*2*pi/3)*x, z:=exp(i*4*pi/3)*x,  Width:=12,  Cercle(0,r), Ligne([x,y,z],1), Ligne([x,0,y,jump,0,z],0),  Label( (x/abs(x)+y/abs(y))/3, "$\alpha$",         (z/abs(z)+y/abs(y))/3, "$\beta$",         (z/abs(z)+x/abs(x))/3, "$\gamma$") ]
Code: [view(-3.5,3.5,-3.5,3.5), Marges(0,0,0,0), size(10),  r:=3, x:=r*exp(-i*pi/6), y:=exp(i*2*pi/3)*x, z:=exp(i*4*pi/3)*x, x:=2*x/3,  y':=bary([y,1.1,x,1]),  Width:=12, Cercle(0,r),  Ligne([x,y,z],1), Ligne([z,y'],0),  LabelDot( x, "$x$", "SE"), LabelDot( y', "$y$", "E"),  Label( x+((z-x)/abs(z-x)+(y-x)/abs(y-x))/3, "$\alpha$",         y'+((z-y')/abs(z-y')+(x-y')/abs(x-y'))/3, "$\beta$",         bary([z,1,x,1,y',1]), "$T$"),  LabelStyle:=right,  Label( y'+((z-y')/abs(z-y')+(y-y')/abs(y-y'))/3.25, "$\pi-\beta$") ]
Code: [view(-3.5,3.5,-3.5,3.5), Marges(0,0,0,0), size(10),  r:=3, X:=r*exp(-i*pi/2.5), Y:=exp(i*2*pi/3)*X, Z:=exp(i*4*pi/3)*X,  x:=bary([Z,2,Y,1,X,7.5]), y:=bary([x,1,Y,2]), z:=[X,x] Inter [Z,y],  Width:=12, Cercle(0,r),  Ligne([X,Y,Z],1), Ligne([Z,y,jump,X,z,jump,Y,x],0),  LabelDot( x, "$x$", "O",1), LabelDot( y, "$y$", "SE",1,0.125), LabelDot( z, "$z$", "N",1),  Label( x+((z-x)/abs(z-x)+(y-x)/abs(y-x))/3, "$\alpha$",         z+((x-z)/abs(x-z)+(y-z)/abs(y-z))/3, "$\beta$",         y+((z-y)/abs(z-y)+(x-y)/abs(x-y))/3, "$\gamma$",         isobar([z,x,y]), "$T$"),  LabelStyle:=right,  Label( z+((Z-z)/abs(Z-z)+(X-z)/abs(X-z))/3, "$\pi-\beta$"),  Label( y+((Y-y)/abs(Y-y)+(Z-y)/abs(Z-y))/3, "$\pi-\gamma$"),  LabelStyle:=left,  Label( x+((X-x)/abs(X-x)+(Y-x)/abs(Y-x))/6, "$\pi-\alpha$") ]
Code: [view(-1.4,1.4,-0.5,2), Marges(0,0,0,0), size(10),  axeX([0,1], 0.5, 1, bottom, 1, "", 2,0),  LineStyle:=solid,  for a in [-2,-1,0,1,2] do     SaveWin(), SetMatrix([a,1,i]),     arc(0,-1,-2,1,1),arc(0,1,2,1,-1),     arc(0,-1/3,-2/3,1/3,1), arc(-2/3,-5/6,-1,1/6,1),     arc(0,1/3,2/3,1/3,-1), arc(2/3,5/6,1,1/6,-1),     RestoreWin(),  od,  LineStyle:=solid, Width:=12, a:=exp(2*i*pi/3), b:=exp(i*pi/3),  FillStyle:=full, FillColor:=cyan,  Path([i*Ymax+0.5, b, line, 0, a, 1, 1, arc, i*Ymax-0.5, line],0),  Width:=4, for z from -1 to 1 step 0.5 do Ddroite(z,z+i) od,  LabelDot(i,"$i$","SE",1),  LabelStyle:=left+bottom, LabelDot(b,"$\,e^{i\pi/3}$","[0.25,i]",1),  ]
Code: [NewMac( "grandCercle",         "[$O:=%1, $R:=%2, $A:=%3, $B:=%4, $U:=Prodvec(A-O,B-O),             $N:=normalize(Prodvec(\n,U)), $s:=Prodscal(U,\n),             if abs(s)<1E-10 then s:=0 fi,             $A':=O+R*N, $B':=O-R*N,             SaveAttr(),             LineStyle:=solid, if s<>0 then Arc3D(A',O,B',R,1,U) else Ligne3D([A',B'],0) fi,             if %5<>Nil then               if %5=1 then  if s<>0 then Arc3D(A',O,B',R,-1,U) fi,               elif %5=0 then  LineStyle:=dotted, if s<>0 then Arc3D(A',O,B',R,-1,U) fi               fi             fi, RestoreAttr()           ]"),  Width:=8, {figure a}  view(-5,5,-5.5,5), Marges(0,0,0,0), size(10),  SaveWin(), R:=2,  view(-5,0,0,5), SetMatrix([-2.5+2.5*i,1,i]), Cercle(0,R),  grandCercle([0,0], R, [R,0], [i*R,0],0),  for k from 0 to 4 do     grandCercle([0,0], R, [0,R], [R*exp(2*i*k*pi/5)],0)  od,  Label(-2.5*i, "$(a)$"),  RestoreWin(), {figure b}  phi:=70*deg,  SaveWin(),  view(0,5,0,5), SetMatrix([2.5+2.5*i,1,i]), Cercle(0,R),  grandCercle([0,0], R, [R,0], [0,R],0), grandCercle([0,0], R, [i*R,0], [0,R],0),  grandCercle([0,0], R, R*normalize([1,-0.5]), R*normalize([i,-0.5]),0),  Ligne([-i*R,i*R,jump,-R,R,jump,-R*exp(i*pi/4),R*exp(i*pi/4),jump,         -R*exp(-i*pi/4),R*exp(-i*pi/4)],0),  Label(-2.5*i, "$(b)$"),  RestoreWin(), {figure c}  SaveWin(), phi:=90*deg,  view(-5,0,-5,0), SetMatrix([-2.5-2.5*i,1,i]), Cercle(0,R),  grandCercle([0,0], R, [R,0], [0,R],0),  grandCercle([0,0], R, [i*R,0], [0,R],0),  Ligne([-i*R,i*R,jump,-R,R,jump,-R*exp(i*pi/4),R*exp(i*pi/4),jump,         -R*exp(-i*pi/4),R*exp(-i*pi/4)],0),  grandCercle([0,0], R, R*normalize(M(1,0,1/2)), -R*normalize(Prodvec(\n,vecK)),0),  grandCercle([0,0], R, R*normalize(M(1,0,-1/2)), -R*normalize(Prodvec(\n,vecK)),0),  Label(-2.5*i, "$(c)$"),  RestoreWin(), {figure d}  SaveWin(), phi:=70*deg,  view(0,5,-5,0), SetMatrix([2.5-2.5*i,1,i]), Cercle(0,R),  for k from 0 to 4 do     grandCercle([0,0], R, [0,R], [R*exp(2*i*k*pi/5)], 0)  od,  A1:=R*normalize([exp(2*i*pi/5),0.5]), B:=R*vecK,  for k from 1 to 4 do     grandCercle([0,0], R, A1, rot3d(B,[0,0,A1],2*k*pi/5),0)  od,  A2:=rot3d(A1, [B,vecK],-2*pi/5),  for k from 1 to 4 do     grandCercle([0,0], R, A2, rot3d(B,[0,0,A2],2*k*pi/5),0)     od,  A3:= sym3d(B,[0,0,Prodvec(A1,A2)]),  for k in [1,4]  do     grandCercle([0,0], R, A3, rot3d(B,[0,0,A3],2*k*pi/5),0)     od,  Label(-2.5*i, "$(d)$"),  RestoreWin() ]
Code: [view(-5,5,-5,5), Marges(0,0,0,0), size(10),  {figure 1}  SaveWin(),  view(-5,5,2,5), SetMatrix([3.5*i,1,i]),  {vue= -5,5,-1.5,1.5}  Ligne(for y in [-1.5,-0.5,0.5,1.5] do -5+i*y,5+i*y,jump od,0),  a:=2/sqrt(3),  for z from 5+a to -5-a step -a do Droite(z+i*1.5, z+i*1.5+exp(-i*pi/3)) od,  for z from 5+a to -5-a step -a do Droite(z+i*1.5, z+i*1.5+exp(-2*i*pi/3)) od,  RestoreWin(), {figure 2}  SaveWin(),  view(-5,5,-1.5,1.5), {vue= -5,5,-1.5,1.5}  Ligne( [for y in [-1.5,-0.5,0.5,1.5] do -5+i*y,5+i*y,jump od,         for x from -5 to 5 step 1 do x-1.5*i,x+1.5*i,jump od         ],0),  a:=2,  for z from 5+a to -5-a step -a do Droite(z+i*1.5, z+i*1.5+exp(i*pi/4)) od,  for z from 5+a to -5-a step -a do Droite(z+i*1.5, z+i*1.5+exp(-i*pi/4)) od,  RestoreWin(),  {figure 3}  SaveWin(),  x1:=-5*sqrt(3)/2, x2:= 5*sqrt(3)/2,  view(-5,5,-5,-2), SetMatrix([-3.5*i,2/sqrt(3),i]), {vue= -5,5,-1.5,1.5}  Ligne( [for y in [-1.5,-0.5,0.5,1.5] do x1+i*y,x2+i*y,jump od,         for x from x1 to x2 step sqrt(3) do x-1.5*i,x+1.5*i,jump od         ],0),  a:=2*sqrt(3),  for z from x2+a to x1-a step -a do Droite(z+i*1.5, z+i*1.5+sqrt(3)-i) od,  for z from x2+a to x1-a step -a do Droite(z+i*1.5, z+i*1.5+sqrt(3)+i) od,  a:=2/sqrt(3),  for z from x2+a to x1-a step -a do Droite(z+i*1.5, z+i*1.5+exp(-i*pi/3)) od,  for z from x2+a to x1-a step -a do Droite(z+i*1.5, z+i*1.5+exp(-2*i*pi/3)) od,  RestoreWin() ]
Fichier source: fig-homer10.teg

Merci beaucoup...

J'ai encore 2 services à demander, j'ai oublier 1 figure, et une 2ème que est une de celle là, mais juste un peu plus détaillée pour mieux comprendre...



c'est censé être du rouge, bleu et noir...j'aimerai juste le cercle limite autour qui n'y est pas, et bien sûr aucune inscription autour...

et


Celle-ci à base de la première qui est parfaite, juste avec tous les autres demi cercle en plus, pas le i\infty, et la couleur...comme vous voulez, comme ça vous arrange, si ca rend le problème trop ...chiant, alors sans couleur

PS: c'est peut-être une maigre compensation en retour, mais plusieurs de mes profs, donc chercheurs, ont téléchargé texgraph. vous faites du sacré boulot !

Bonsoir homer,

Juste une question, sais-tu à partir de quoi est obtenu le pavage du disque hyperbolique?

Re,

On peut voir le problème de plusieurs façon:
- en hexagones (rouge)
- en losanges (bleu clair)
- en triangles rectangles (angles de 90, 45 et 30°).

On le voit souvent comme le pavage obtenu par réflexion du simplex de dimension 2 : un triangle T(a,b,c) avec ses angles pi/a, pi/b et pi/c.

cette figure est la réflexion du triangle T(2,4,6) ie d'angle PI/2 = 90°, pi/4=45° et pi/6=30°.

En esperant t'avoir aidé.